configure.in

   1 dnl Process this file with autoconf to create a configure script.
   2
   3 dnl General initialization.
   4 AC_REVISION([$Id: configure.in,v 1.77 2004/01/02 01:49:15 entrope Exp $])
   5 AC_PREREQ(2.59)
   6 AC_INIT([srvx],[1.3],[srvx-bugs@lists.sourceforge.net])
   7 CODENAME=surge
   8 AC_CONFIG_HEADERS(src/config.h)
   9 AC_CONFIG_SRCDIR(src/opserv.c)
  10 dnl AM_CANONICAL_TARGET must be before AM_INIT_AUTOMAKE() or autoconf whines
  11 AC_CANONICAL_TARGET
  12 AM_INIT_AUTOMAKE([gnu 1.6])
  13 AM_MAINTAINER_MODE
  14
  15 dnl Compiler/runtime feature checks.
  16 AC_TYPE_SIGNAL
  17 AC_C_CONST
  18 AC_C_INLINE
  19
  20 dnl Checks for programs.
  21 AC_PROG_AWK
  22 AC_PROG_CC
  23 AC_PROG_RANLIB
  24 AC_PROG_INSTALL
  25 AC_PROG_LN_S
  26 AC_PROG_MAKE_SET
  27 AC_PROG_GCC_TRADITIONAL
  28
  29 dnl nice that unixes can all follow a standard.
  30 case $target in
  31   *-freebsd2* | *-freebsdelf2* | *-freebsd*out3*)
  32     ANSI_SRC=""
  33     ;;
  34   *-freebsd3* | *-freebsdelf3* | *-freebsd*out3*)
  35     ANSI_SRC=""
  36     AC_DEFINE(BROKEN_REGEX, 1, [Define if the system regex library is unreliable.])
  37         BROKEN_REGEX=yes
  38     ;;
  39   *-solaris*)
  40     EXTRA_DEFINE="-D__SOLARIS__"
  41     ANSI_SRC="-fno-builtin"
  42     ;;
  43   *-cygwin)
  44     ANSI_SRC="-fno-builtin"
  45     ;;
  46   *-linux*)
  47     dnl -D_GNU_SOURCE needed for strsignal()
  48     EXTRA_DEFINE="-D_GNU_SOURCE"
  49     ANSI_SRC=""
  50     ;;
  51   *)
  52     ANSI_SRC=""
  53     ;;
  54 esac
  55 CFLAGS="$CFLAGS $EXTRA_DEFINE"
  56
  57 dnl Checks for libraries.
  58 AC_CHECK_LIB(socket, socket)
  59 AC_CHECK_LIB(nsl, gethostbyname)
  60
  61 dnl Checks for header files.
  62 AC_HEADER_STDC
  63
  64 dnl will be used for portability stuff
  65 AC_HEADER_TIME
  66 AC_STRUCT_TM
  67
  68 dnl Would rather not bail on headers, BSD has alot of the functions elsewhere. -Jedi
  69 AC_CHECK_HEADERS(fcntl.h malloc.h netdb.h netinet/in.h sys/resource.h sys/timeb.h sys/times.h sys/param.h sys/socket.h sys/time.h sys/types.h sys/wait.h unistd.h getopt.h memory.h regex.h arpa/inet.h sys/mman.h sys/stat.h dirent.h,,)
  70
  71 dnl Cygwin does not have d_type in struct dirent.  We use stat() as a fallback.
  72 AC_CHECK_MEMBER([struct dirent.d_type],
  73         [AC_DEFINE(HAVE_DIRENT_D_TYPE, 1, [Define if struct dirent exists and includes the d_type element.])],,[#include <dirent.h>])
  74
  75 dnl portability stuff, hurray! -Jedi
  76 AC_CHECK_MEMBER([struct sockaddr.sa_len],
  77                 [AC_DEFINE([HAVE_SOCKADDR_SA_LEN],,[Define if struct sockaddr has sa_len field])],
  78                 [],[#include <sys/types.h>
  79 #include <sys/socket.h>])
  80 AC_CHECK_MEMBER([struct addrinfo.ai_flags],
  81                 [AC_DEFINE([HAVE_STRUCT_ADDRINFO],,[Define if struct addrinfo declared])],
  82                 [],[#include <sys/types.h>
  83 #include <sys/socket.h>
  84 #include <netdb.h>])
  85 AC_CHECK_FUNCS(gettimeofday)
  86 if test $ac_cv_func_gettimeofday = no; then
  87   AC_CHECK_FUNCS(ftime,,AC_MSG_ERROR([ftime or gettimeofday required.  srvx build will fail.]))
  88 fi
  89
  90 dnl We have fallbacks in case these are missing, so just check for them.
  91 AC_CHECK_FUNCS(freeaddrinfo getaddrinfo getnameinfo getpagesize memcpy memset strdup strerror strsignal localtime_r setrlimit getopt getopt_long regcomp regexec regfree sysconf,,)
  92
  93 dnl Check for absolutely required library functions.
  94 AC_CHECK_FUNCS(select socket strcspn strspn strtod strtoul,,AC_MSG_ERROR([a required function was not found.  srvx build will fail.]))
  95
  96 dnl Check for functions (and how to get them).
  97 AC_FUNC_ALLOCA
  98 AC_FUNC_MMAP
  99
 100 AC_CACHE_CHECK([for sin_len], ac_cv_sin_len,
 101 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 102 #include <netinet/in.h>],[struct sockaddr_in *sin; sin->sin_len = 0;])],
 103 ac_cv_sin_len="yes", ac_cv_sin_len="no")])
 104 if test $ac_cv_sin_len = yes ; then
 105   AC_DEFINE(HAVE_SIN_LEN, 1, [Define if struct sockaddr_in contains a sin_len field])
 106 fi
 107
 108 dnl Check for socklen_t.  In traditional BSD this is an int, but some
 109 dnl OSes use a different type.  Test until we find something that will
 110 dnl work properly.  Test borrowed from a patch submitted for Python.
 111 AC_CHECK_TYPE([socklen_t], ,[
 112   AC_MSG_CHECKING([for socklen_t equivalent])
 113   AC_CACHE_VAL([curl_cv_socklen_t_equiv],
 114   [
 115 dnl Systems have either "struct sockaddr*" or "void*" as second
 116 dnl arg to getpeername.
 117     curl_cv_socklen_t_equiv=
 118     for arg2 in "struct sockaddr" void ; do
 119       for t in int size_t unsigned long "unsigned long" ; do
 120         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 121 #include <sys/socket.h>
 122 int getpeername (int $arg2 *, $t *);]], [[$t len;
 123   getpeername(0, 0, &len);]])],[curl_cv_socklen_t_equiv="$t"
 124   break],[])
 125       done
 126     done
 127   ])
 128   AC_MSG_RESULT($curl_cv_socklen_t_equiv)
 129   AC_DEFINE_UNQUOTED(socklen_t, $curl_cv_socklen_t_equiv,
 130       [type to use in place of socklen_t if not defined])],
 131   [#include <sys/types.h>
 132 #include<sys/socket.h>])
 133
 134 dnl Can only check with -Werror, but the rest of configure doesn't like -Werror
 135 OLD_CFLAGS=$CFLAGS
 136 CFLAGS="$CFLAGS -W -Wall -Werror"
 137
 138 dnl Now figure out how to printf() a time_t
 139 AC_MSG_CHECKING(for time_t format)
 140 AC_CACHE_VAL(ac_cv_fmt_time_t, [
 141 ac_cv_fmt_time_t=no
 142 AC_COMPILE_IFELSE([#include <sys/types.h>
 143 #include <stdio.h>
 144 void myfunc(void) {
 145   time_t test=0;
 146   printf("%li", test);
 147 }], ac_cv_fmt_time_t="\"%li\"")
 148 if test $ac_cv_fmt_time_t = no; then
 149 AC_COMPILE_IFELSE([#include <sys/types.h>
 150 #include <stdio.h>
 151 void myfunc(void) {
 152   time_t test=0;
 153   printf("%i", test);
 154 }], ac_cv_fmt_time_t="\"%i\"")
 155 fi
 156 if test $ac_cv_fmt_time_t = no; then
 157 AC_MSG_ERROR([Cannot detect format string for time_t
 158 Please check sys/types.h for the typedef of time_t and submit to a developer])
 159 fi
 160 ])
 161 AC_DEFINE_UNQUOTED(FMT_TIME_T, $ac_cv_fmt_time_t, [Define to printf format for a time_t variable])
 162 AC_MSG_RESULT($ac_cv_fmt_time_t)
 163
 164 dnl How to copy one va_list to another?
 165 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy, [AC_LINK_IFELSE(
 166   [AC_LANG_PROGRAM([#include <stdarg.h>], [va_list ap1, ap2; va_copy(ap1, ap2);])],
 167   [ac_cv_c_va_copy="yes"],
 168   [ac_cv_c_va_copy="no"]
 169 )])
 170 if test "$ac_cv_c_va_copy" = "yes" ; then
 171   AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 172 fi
 173
 174 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy, [AC_LINK_IFELSE(
 175   [AC_LANG_PROGRAM([#include <stdarg.h>], [va_list ap1, ap2; __va_copy(ap1, ap2);])],
 176   [ac_cv_c___va_copy="yes"],
 177   [ac_cv_c___va_copy="no"]
 178 )])
 179 if test "$ac_cv_c___va_copy" = "yes" ; then
 180   AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 181 fi
 182
 183 dnl Now fix things back up
 184 CFLAGS=$OLD_CFLAGS
 185
 186 dnl Optional features.
 187 AC_MSG_CHECKING(which malloc to use)
 188 AC_ARG_WITH(malloc,
 189 [  --with-malloc=type      Enables use of a special malloc library; one of:
 190                           system (the default), boehm-gc, dmalloc, mpatrol, srvx, slab],
 191 [],
 192 [withval="system"])
 193 if test "x$withval" = "xsystem" ; then
 194   AC_MSG_RESULT(system)
 195   AC_DEFINE(WITH_MALLOC_SYSTEM, 1, [Define if using the system's malloc])
 196 elif test "x$withval" = "xdmalloc" ; then
 197   AC_MSG_RESULT(dmalloc)
 198   AC_CHECK_HEADERS(dmalloc.h,,AC_MSG_ERROR([dmalloc header file missing.  dmalloc build will fail.]))
 199   AC_CHECK_LIB(dmalloc,malloc,,AC_MSG_ERROR([dmalloc library is missing.  dmalloc build will fail.]))
 200   AC_DEFINE(WITH_MALLOC_DMALLOC, 1, [Define if using the dmalloc debugging malloc package])
 201 elif test "x$withval" = "xmpatrol" ; then
 202   AC_MSG_RESULT(mpatrol)
 203   AC_CHECK_HEADERS(mpatrol.h,,AC_MSG_ERROR([mpatrol header file missing.  mpatrol build will fail.]))
 204   dnl Using mpatrol requires linking against libelf, at least on Linux.
 205   AC_CHECK_LIB(elf, elf_begin)
 206   AC_CHECK_LIB(mpatrol,__mp_atexit,,AC_MSG_ERROR([mpatrol library is missing completely.  mpatrol build will fail.]))
 207   AC_DEFINE(WITH_MALLOC_MPATROL, 1, [Define if using the mpatrol malloc debugging package])
 208 elif test "x$withval" = "xboehm-gc" ; then
 209   AC_MSG_RESULT(boehm-gc)
 210   AC_CHECK_HEADERS(gc/gc.h,,AC_MSG_ERROR([Boehm GC header file missing.  boehm-gc build will fail.]))
 211   AC_CHECK_LIB(dl, dlopen, , AC_MSG_ERROR([libdl library is missing.  boehm-gc build will fail.]))
 212   AC_CHECK_LIB(gc, GC_gcollect, , AC_MSG_ERROR([Boehm GC library is missing.  boehm-gc build will fail.]))
 213   AC_DEFINE(WITH_MALLOC_BOEHM_GC, 1, [Define if using the Boehm GC to garbage collect and check memory leaks])
 214 elif test "x$withval" = "xsrvx" ; then
 215   AC_MSG_RESULT(srvx)
 216   AC_DEFINE(WITH_MALLOC_SRVX, 1, [Define if using the srvx internal debug allocator])
 217   MODULE_OBJS="$MODULE_OBJS alloc-srvx.\$(OBJEXT)"
 218 elif test "x$withval" = "xslab" ; then
 219   AC_MSG_RESULT(slab)
 220   AC_DEFINE(WITH_MALLOC_SLAB, 1, [Define if using the slab internal debug allocator])
 221   MODULE_OBJS="$MODULE_OBJS alloc-slab.\$(OBJEXT)"
 222 else
 223   AC_MSG_ERROR([Unknown malloc type $withval])
 224 fi
 225
 226 AC_MSG_CHECKING(which protocol to use)
 227 AC_ARG_WITH(protocol,
 228 [  --with-protocol=name    Choose IRC dialect to support; one of:
 229                           p10 (the default), bahamut],
 230 [],
 231 [withval="p10"])
 232 if test "x$withval" = "xp10" ; then
 233   AC_MSG_RESULT(P10)
 234   AC_DEFINE(WITH_PROTOCOL_P10, 1, [Define if using the P10 dialect of IRC])
 235   MODULE_OBJS="$MODULE_OBJS proto-p10.\$(OBJEXT)"
 236   PROTO_FILES=proto-p10.c
 237 elif test "x$withval" = "xbahamut" ; then
 238   AC_MSG_RESULT(Bahamut)
 239   AC_DEFINE(WITH_PROTOCOL_BAHAMUT, 1, [Define if using the Bahamut dialect of IRC])
 240   MODULE_OBJS="$MODULE_OBJS proto-bahamut.\$(OBJEXT)"
 241 else
 242   AC_MSG_ERROR([Unknown IRC dialect $withval])
 243 fi
 244
 245 AC_ARG_WITH(getopt,
 246 [  --without-getopt        Disables building of the GNU getopt library],
 247 [if test "$withval" = no; then
 248   AC_DEFINE(IGNORE_GETOPT, 1, [Define to disable built-in getopt library])
 249 fi])
 250
 251 AC_MSG_CHECKING(whether to enable tokenization)
 252 AC_ARG_ENABLE(tokens,
 253 [  --disable-tokens        Disables tokenization of P10 protocol output
 254                            (tokens required if linking to ircu 2.10.11)],
 255 [],[enableval=yes])
 256 if test "z$enableval" = zno ; then
 257   AC_MSG_RESULT(no)
 258 else
 259   AC_DEFINE(ENABLE_TOKENS, 1, [Define if tokenized P10 desired])
 260   AC_MSG_RESULT(yes)
 261 fi
 262
 263 AC_MSG_CHECKING(whether to enable debug behaviors)
 264 AC_ARG_ENABLE(debug,
 265 [  --enable-debug          Enables debugging behaviors],
 266 [
 267   CPPFLAGS="$CPPFLAGS"
 268   AC_MSG_RESULT(yes)
 269 ],
 270 [
 271   CPPFLAGS="$CPPFLAGS -DNDEBUG"
 272   AC_MSG_RESULT(no)
 273 ])
 274
 275 if test -e src ; then
 276   if test ! -d src ; then
 277     AC_MSG_ERROR([src exists but is not a directory; please move it out of the way.])
 278   fi
 279 else
 280   mkdir src
 281 fi
 282 AC_MSG_CHECKING(for extra module files)
 283 MODULE_DEFINES="src/modules-list.h"
 284 echo > $MODULE_DEFINES
 285 touch $MODULE_DEFINES
 286 AC_ARG_ENABLE(modules,
 287 [  --enable-modules=list,of,modules   Enable extra modules],
 288 [
 289   OIFS="$IFS"
 290   IFS=','
 291   EXTRA_MODULE_OBJS=""
 292   module_list=""
 293   dnl Must use a separate file because autoconf can't stand newlines in an AC_SUBSTed variable.
 294   for module in $enableval ; do
 295     module=`echo $module | sed -e s/^mod-// -e s/\.c\$//`
 296     EXTRA_MODULE_OBJS="$EXTRA_MODULE_OBJS mod-$module.\$(OBJEXT)"
 297     module_list="$module_list $module"
 298     echo "WITH_MODULE($module)" >> $MODULE_DEFINES
 299   done
 300   IFS="$OIFS"
 301   MODULE_OBJS="$MODULE_OBJS $EXTRA_MODULE_OBJS"
 302   AC_MSG_RESULT($module_list)
 303 ],
 304 [
 305   AC_MSG_RESULT(none)
 306 ])
 307
 308 MY_SUBDIRS=""
 309 RX_INCLUDES=""
 310 RX_LIBS=""
 311 if test "${BROKEN_REGEX}" = yes -o "${ac_cv_func_regcomp}" = no; then
 312   MY_SUBDIRS="rx $MY_SUBDIRS"
 313   RX_INCLUDES="-I../rx"
 314   RX_LIBS="../rx/librx.a"
 315 fi
 316 MY_SUBDIRS="$MY_SUBDIRS src"
 317 CFLAGS="$CFLAGS $ANSI_SRC -W -Wall"
 318 if test "z$USE_MAINTAINER_MODE" = zyes ; then
 319   CFLAGS="$CFLAGS -Werror"
 320 fi
 321
 322 AC_DEFINE_UNQUOTED(CODENAME, "${CODENAME}", [Code name for this release])
 323 AC_SUBST(MODULE_OBJS)
 324 AC_SUBST(MY_SUBDIRS)
 325 AC_SUBST(RX_INCLUDES)
 326 AC_SUBST(RX_LIBS)
 327 AC_CONFIG_FILES(Makefile rx/Makefile src/Makefile)
 328 AC_OUTPUT