configure.in

   1 dnl Process this file with autoconf to create a configure script.
   2
   3 dnl General initialization.
   4 AC_PREREQ(2.59)
   5 AC_INIT([srvx],[1.3.1],[srvx-bugs@lists.sourceforge.net])
   6 CODENAME=surge
   7 AC_CONFIG_HEADERS(src/config.h)
   8 AC_CONFIG_SRCDIR(src/opserv.c)
   9 dnl AM_CANONICAL_TARGET must be before AM_INIT_AUTOMAKE() or autoconf whines
  10 AC_CANONICAL_TARGET
  11 AM_INIT_AUTOMAKE([gnu 1.6])
  12 AM_MAINTAINER_MODE
  13
  14 dnl Compiler/runtime feature checks.
  15 AC_TYPE_SIGNAL
  16 AC_C_CONST
  17 dnl "const" *should* be in the -Werror section, but that breaks Linux. gg gcc.
  18
  19 dnl Checks for programs.
  20 AC_PROG_AWK
  21 AC_PROG_CC
  22 AC_PROG_INSTALL
  23 AC_PROG_LIBTOOL
  24 AC_PROG_LN_S
  25 AC_PROG_MAKE_SET
  26 AC_PROG_GCC_TRADITIONAL
  27
  28 dnl Look for a git client
  29 AC_CHECK_PROGS(GIT, [git])
  30 AM_CONDITIONAL(HAS_GIT, test z$GIT != z)
  31
  32 dnl nice that unixes can all follow a standard.
  33 case $target in
  34   *-freebsd2* | *-freebsdelf2* | *-freebsd*out3*)
  35     ANSI_SRC=""
  36     ;;
  37   *-freebsd3* | *-freebsdelf3* | *-freebsd*out3*)
  38     ANSI_SRC=""
  39     AC_DEFINE(BROKEN_REGEX, 1, [Define if the system regex library is unreliable.])
  40         BROKEN_REGEX=yes
  41     ;;
  42   *-solaris*)
  43     EXTRA_DEFINE="-D__SOLARIS__"
  44     ANSI_SRC="-fno-builtin"
  45     ;;
  46   *-cygwin)
  47     ANSI_SRC="-fno-builtin"
  48     ;;
  49   *-linux*)
  50     dnl -D_GNU_SOURCE needed for strsignal()
  51     EXTRA_DEFINE="-D_GNU_SOURCE"
  52     ANSI_SRC=""
  53     ;;
  54   *)
  55     ANSI_SRC=""
  56     ;;
  57 esac
  58 CFLAGS="$CFLAGS $EXTRA_DEFINE"
  59
  60 dnl Checks for libraries.
  61 AC_CHECK_LIB(socket, socket)
  62 AC_CHECK_LIB(nsl, gethostbyname)
  63
  64 dnl Checks for header files.
  65 AC_HEADER_STDC
  66
  67 dnl will be used for portability stuff
  68 AC_HEADER_TIME
  69 AC_STRUCT_TM
  70
  71 dnl Would rather not bail on headers, BSD has alot of the functions elsewhere. -Jedi
  72 AC_CHECK_HEADERS(fcntl.h malloc.h netdb.h arpa/inet.h netinet/in.h sys/resource.h sys/timeb.h sys/times.h sys/param.h sys/socket.h sys/time.h sys/types.h sys/wait.h unistd.h getopt.h memory.h regex.h arpa/inet.h sys/mman.h sys/stat.h dirent.h sys/epoll.h,,)
  73
  74 dnl portability stuff, hurray! -Jedi
  75 AC_CHECK_MEMBER([struct sockaddr.sa_len],
  76                 [AC_DEFINE([HAVE_SOCKADDR_SA_LEN],,[Define if struct sockaddr has sa_len field])],
  77                 [],[#include <sys/types.h>
  78 #include <sys/socket.h>])
  79 AC_CHECK_MEMBER([struct addrinfo.ai_flags],
  80                 [AC_DEFINE([HAVE_STRUCT_ADDRINFO],,[Define if struct addrinfo declared])],
  81                 [],[#include <sys/types.h>
  82 #include <sys/socket.h>
  83 #include <netdb.h>])
  84
  85 dnl We have fallbacks in case these are missing, so just check for them.
  86 AC_CHECK_FUNCS(freeaddrinfo getaddrinfo getnameinfo getpagesize memcpy memset strdup strerror strsignal localtime_r setrlimit getopt getopt_long regcomp regexec regfree sysconf inet_aton epoll_create select gettimeofday,,)
  87
  88 dnl Check for the fallbacks for functions missing above.
  89 if test $ac_cv_func_gettimeofday = no; then
  90   AC_CHECK_FUNCS(ftime,,AC_MSG_ERROR([ftime or gettimeofday required.  srvx build will fail.]))
  91 fi
  92
  93 dnl Check for absolutely required library functions.
  94 AC_CHECK_FUNCS(socket strcspn strspn strtod strtoul,,AC_MSG_ERROR([a required function was not found.  srvx build will fail.]))
  95
  96 dnl Check for functions (and how to get them).
  97 AC_FUNC_ALLOCA
  98 AC_FUNC_MMAP
  99
 100 AC_CACHE_CHECK([for sin_len], ac_cv_sin_len,
 101 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 102 #include <netinet/in.h>],[struct sockaddr_in *sin; sin->sin_len = 0;])],
 103 ac_cv_sin_len="yes", ac_cv_sin_len="no")])
 104 if test $ac_cv_sin_len = yes ; then
 105   AC_DEFINE(HAVE_SIN_LEN, 1, [Define if struct sockaddr_in contains a sin_len field])
 106 fi
 107
 108 dnl Check for socklen_t.  In traditional BSD this is an int, but some
 109 dnl OSes use a different type.  Test until we find something that will
 110 dnl work properly.  Test borrowed from a patch submitted for Python.
 111 AC_CHECK_TYPE([socklen_t], ,[
 112   AC_MSG_CHECKING([for socklen_t equivalent])
 113   AC_CACHE_VAL([curl_cv_socklen_t_equiv],
 114   [
 115 dnl Systems have either "struct sockaddr*" or "void*" as second
 116 dnl arg to getpeername.
 117     curl_cv_socklen_t_equiv=
 118     for arg2 in "struct sockaddr" void ; do
 119       for t in int size_t unsigned long "unsigned long" ; do
 120         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 121 #include <sys/socket.h>
 122 int getpeername (int $arg2 *, $t *);]], [[$t len;
 123   getpeername(0, 0, &len);]])],[curl_cv_socklen_t_equiv="$t"
 124   break],[])
 125       done
 126     done
 127   ])
 128   AC_MSG_RESULT($curl_cv_socklen_t_equiv)
 129   AC_DEFINE_UNQUOTED(socklen_t, $curl_cv_socklen_t_equiv,
 130       [type to use in place of socklen_t if not defined])],
 131   [#include <sys/types.h>
 132 #include<sys/socket.h>])
 133
 134 dnl Can only check with -Werror, but the rest of configure doesn't like -Werror
 135 OLD_CFLAGS=$CFLAGS
 136 CFLAGS="$CFLAGS -W -Wall -Werror"
 137 if test "z$USE_MAINTAINER_MODE" = zyes ; then
 138   CFLAGS="$CFLAGS -ansi"
 139 fi
 140
 141 dnl Check for post-C89 keywords
 142 AC_C_INLINE
 143
 144 dnl Now figure out how to printf() a time_t
 145 AC_MSG_CHECKING(for time_t format)
 146 AC_CACHE_VAL(ac_cv_fmt_time_t, [
 147 ac_cv_fmt_time_t=no
 148 AC_COMPILE_IFELSE([#include <sys/types.h>
 149 #include <stdio.h>
 150 void myfunc(void) {
 151   time_t test=0;
 152   printf("%li", test);
 153 }], ac_cv_fmt_time_t="\"%li\"")
 154 if test $ac_cv_fmt_time_t = no; then
 155 AC_COMPILE_IFELSE([#include <sys/types.h>
 156 #include <stdio.h>
 157 void myfunc(void) {
 158   time_t test=0;
 159   printf("%i", test);
 160 }], ac_cv_fmt_time_t="\"%i\"")
 161 fi
 162 if test $ac_cv_fmt_time_t = no; then
 163 AC_MSG_ERROR([Cannot detect format string for time_t
 164 Please check sys/types.h for the typedef of time_t and submit to a developer])
 165 fi
 166 ])
 167 AC_DEFINE_UNQUOTED(FMT_TIME_T, $ac_cv_fmt_time_t, [Define to printf format for a time_t variable])
 168 AC_MSG_RESULT($ac_cv_fmt_time_t)
 169
 170 dnl How to copy one va_list to another?
 171 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy, [AC_LINK_IFELSE(
 172   [AC_LANG_PROGRAM([#include <stdarg.h>], [va_list ap1, ap2; va_copy(ap1, ap2);])],
 173   [ac_cv_c_va_copy="yes"],
 174   [ac_cv_c_va_copy="no"]
 175 )])
 176 if test "$ac_cv_c_va_copy" = "yes" ; then
 177   AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 178 fi
 179
 180 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy, [AC_LINK_IFELSE(
 181   [AC_LANG_PROGRAM([#include <stdarg.h>], [va_list ap1, ap2; __va_copy(ap1, ap2);])],
 182   [ac_cv_c___va_copy="yes"],
 183   [ac_cv_c___va_copy="no"]
 184 )])
 185 if test "$ac_cv_c___va_copy" = "yes" ; then
 186   AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 187 fi
 188
 189 dnl Now fix things back up
 190 CFLAGS=$OLD_CFLAGS
 191
 192 dnl Optional features.
 193 AC_MSG_CHECKING(which malloc to use)
 194 AC_ARG_WITH(malloc,
 195 [  --with-malloc=type      Enables use of a special malloc library; one of:
 196                           system (the default), boehm-gc, dmalloc, mpatrol, srvx, slab],
 197 [],
 198 [withval="system"])
 199 if test "x$withval" = "xsystem" ; then
 200   AC_MSG_RESULT(system)
 201   AC_DEFINE(WITH_MALLOC_SYSTEM, 1, [Define if using the system's malloc])
 202 elif test "x$withval" = "xdmalloc" ; then
 203   AC_MSG_RESULT(dmalloc)
 204   AC_CHECK_HEADERS(dmalloc.h,,AC_MSG_ERROR([dmalloc header file missing.  dmalloc build will fail.]))
 205   AC_CHECK_LIB(dmalloc,malloc,,AC_MSG_ERROR([dmalloc library is missing.  dmalloc build will fail.]))
 206   AC_DEFINE(WITH_MALLOC_DMALLOC, 1, [Define if using the dmalloc debugging malloc package])
 207 elif test "x$withval" = "xmpatrol" ; then
 208   AC_MSG_RESULT(mpatrol)
 209   AC_CHECK_HEADERS(mpatrol.h,,AC_MSG_ERROR([mpatrol header file missing.  mpatrol build will fail.]))
 210   dnl Using mpatrol requires linking against libelf, at least on Linux.
 211   AC_CHECK_LIB(elf, elf_begin)
 212   AC_CHECK_LIB(mpatrol,__mp_atexit,,AC_MSG_ERROR([mpatrol library is missing completely.  mpatrol build will fail.]))
 213   AC_DEFINE(WITH_MALLOC_MPATROL, 1, [Define if using the mpatrol malloc debugging package])
 214 elif test "x$withval" = "xboehm-gc" ; then
 215   AC_MSG_RESULT(boehm-gc)
 216   AC_CHECK_HEADERS(gc/gc.h,,AC_MSG_ERROR([Boehm GC header file missing.  boehm-gc build will fail.]))
 217   AC_CHECK_LIB(dl, dlopen, , AC_MSG_ERROR([libdl library is missing.  boehm-gc build will fail.]))
 218   AC_CHECK_LIB(gc, GC_gcollect, , AC_MSG_ERROR([Boehm GC library is missing.  boehm-gc build will fail.]))
 219   AC_DEFINE(WITH_MALLOC_BOEHM_GC, 1, [Define if using the Boehm GC to garbage collect and check memory leaks])
 220 elif test "x$withval" = "xsrvx" ; then
 221   AC_MSG_RESULT(srvx)
 222   AC_DEFINE(WITH_MALLOC_SRVX, 1, [Define if using the srvx internal debug allocator])
 223   MODULE_OBJS="$MODULE_OBJS alloc-srvx.\$(OBJEXT)"
 224 elif test "x$withval" = "xslab" ; then
 225   AC_MSG_RESULT(slab)
 226   AC_DEFINE(WITH_MALLOC_SLAB, 1, [Define if using the slab internal debug allocator])
 227   MODULE_OBJS="$MODULE_OBJS alloc-slab.\$(OBJEXT)"
 228 else
 229   AC_MSG_ERROR([Unknown malloc type $withval])
 230 fi
 231
 232 AC_MSG_CHECKING(which protocol to use)
 233 AC_ARG_WITH(protocol,
 234 [  --with-protocol=name    Choose IRC dialect to support; one of:
 235                           p10 (the default), bahamut],
 236 [],
 237 [withval="p10"])
 238 if test "x$withval" = "xp10" ; then
 239   AC_MSG_RESULT(P10)
 240   AC_DEFINE(WITH_PROTOCOL_P10, 1, [Define if using the P10 dialect of IRC])
 241   MODULE_OBJS="$MODULE_OBJS proto-p10.\$(OBJEXT)"
 242   PROTO_FILES=proto-p10.c
 243 elif test "x$withval" = "xbahamut" ; then
 244   AC_MSG_RESULT(Bahamut)
 245   AC_DEFINE(WITH_PROTOCOL_BAHAMUT, 1, [Define if using the Bahamut dialect of IRC])
 246   MODULE_OBJS="$MODULE_OBJS proto-bahamut.\$(OBJEXT)"
 247 else
 248   AC_MSG_ERROR([Unknown IRC dialect $withval])
 249 fi
 250
 251 AC_MSG_CHECKING([I/O multiplexing backends])
 252 IOMUXES=""
 253
 254 if test "x$ac_cv_func_select" = xyes ; then
 255   AC_DEFINE(WITH_IOSET_SELECT, 1, [Define if using the select() I/O backend])
 256   MODULE_OBJS="$MODULE_OBJS ioset-select.\$(OBJEXT)"
 257   IOMUXES="$IOMUXES select"
 258 fi
 259
 260 AC_ARG_WITH([epoll],
 261 [  --without-epoll         Disables the epoll_*() I/O backend],
 262 [],
 263 [withval="$ac_cv_func_epoll_create"])
 264 if test "x$withval" = xyes ; then
 265   AC_DEFINE(WITH_IOSET_EPOLL, 1, [Define if using the epoll I/O backend])
 266   MODULE_OBJS="$MODULE_OBJS ioset-epoll.\$(OBJEXT)"
 267   IOMUXES="$IOMUXES epoll"
 268 fi
 269
 270 IOMUXES=`echo $IOMUXES | sed 's/^ +//'`
 271 if test "x$IOMUXES" = "x" ; then
 272   AC_MSG_ERROR([No supported I/O multiplexing backend found])
 273 else
 274   AC_MSG_RESULT($IOMUXES)
 275 fi
 276
 277 AC_ARG_WITH(getopt,
 278 [  --without-getopt        Disables building of the GNU getopt library],
 279 [if test "$withval" = no; then
 280   AC_DEFINE(IGNORE_GETOPT, 1, [Define to disable built-in getopt library])
 281 fi])
 282
 283 AC_MSG_CHECKING(whether to enable tokenization)
 284 AC_ARG_ENABLE(tokens,
 285 [  --disable-tokens        Disables tokenization of P10 protocol output
 286                            (tokens required if linking to ircu 2.10.11)],
 287 [],[enableval=yes])
 288 if test "z$enableval" = zno ; then
 289   AC_MSG_RESULT(no)
 290 else
 291   AC_DEFINE(ENABLE_TOKENS, 1, [Define if tokenized P10 desired])
 292   AC_MSG_RESULT(yes)
 293 fi
 294
 295 AC_MSG_CHECKING(whether to enable debug behaviors)
 296 AC_ARG_ENABLE(debug,
 297 [  --enable-debug          Enables debugging behaviors],
 298 [
 299   CPPFLAGS="$CPPFLAGS"
 300   AC_MSG_RESULT(yes)
 301 ],
 302 [
 303   CPPFLAGS="$CPPFLAGS -DNDEBUG"
 304   AC_MSG_RESULT(no)
 305 ])
 306
 307 if test -e src ; then
 308   if test ! -d src ; then
 309     AC_MSG_ERROR([src exists but is not a directory; please move it out of the way.])
 310   fi
 311 else
 312   mkdir src
 313 fi
 314 AC_MSG_CHECKING(for extra module files)
 315 MODULE_DEFINES="src/modules-list.h"
 316 echo > $MODULE_DEFINES
 317 touch $MODULE_DEFINES
 318 AC_ARG_ENABLE(modules,
 319 [  --enable-modules=list,of,modules   Enable extra modules],
 320 [
 321   OIFS="$IFS"
 322   IFS=','
 323   EXTRA_MODULE_OBJS=""
 324   module_list=""
 325   dnl Must use a separate file because autoconf can't stand newlines in an AC_SUBSTed variable.
 326   for module in $enableval ; do
 327     module=`echo $module | sed -e s/^mod-// -e s/\.c\$//`
 328     EXTRA_MODULE_OBJS="$EXTRA_MODULE_OBJS mod-$module.\$(OBJEXT)"
 329     module_list="$module_list $module"
 330     echo "WITH_MODULE($module)" >> $MODULE_DEFINES
 331   done
 332   IFS="$OIFS"
 333   MODULE_OBJS="$MODULE_OBJS $EXTRA_MODULE_OBJS"
 334   AC_MSG_RESULT($module_list)
 335 ],
 336 [
 337   AC_MSG_RESULT(none)
 338 ])
 339
 340 MY_SUBDIRS=""
 341 RX_INCLUDES=""
 342 RX_LIBS=""
 343 if test "${BROKEN_REGEX}" = yes -o "${ac_cv_func_regcomp}" = no; then
 344   MY_SUBDIRS="rx $MY_SUBDIRS"
 345   RX_INCLUDES="-I../rx"
 346   RX_LIBS="../rx/librx.a"
 347 fi
 348 MY_SUBDIRS="$MY_SUBDIRS src"
 349 CFLAGS="$CFLAGS $ANSI_SRC -W -Wall"
 350 if test "z$USE_MAINTAINER_MODE" = zyes ; then
 351   CFLAGS="$CFLAGS -Werror -ansi"
 352 fi
 353
 354 AC_DEFINE_UNQUOTED(CODENAME, "${CODENAME}", [Code name for this release])
 355 AC_SUBST(MODULE_OBJS)
 356 AC_SUBST(MY_SUBDIRS)
 357 AC_SUBST(RX_INCLUDES)
 358 AC_SUBST(RX_LIBS)
 359 AC_CONFIG_FILES(Makefile rx/Makefile src/Makefile)
 360 AC_OUTPUT