ircd/ircd_parser.y

   1 /*
   2  * ircd_parser.y: A yacc/bison parser for ircd config files.
   3  * This is part of ircu, an Internet Relay Chat server.
   4  * The contents of this file are Copyright 2001 Diane Bruce,
   5  * Andrew Miller, the ircd-hybrid team and the ircu team.
   6  *  This program is free software; you can redistribute it and/or modify
   7  *  it under the terms of the GNU General Public License as published by
   8  *  the Free Software Foundation; either version 2 of the License, or
   9  *  (at your option) any later version.
  10  *
  11  *  This program is distributed in the hope that it will be useful,
  12  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *  GNU General Public License for more details.
  15  *
  16  *  You should have received a copy of the GNU General Public License
  17  *  along with this program; if not, write to the Free Software
  18  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307,
  19  *  USA.
  20  * $Id$
  21  */
  22 %{
  23
  24 #include "config.h"
  25 #include "s_conf.h"
  26 #include "class.h"
  27 #include "client.h"
  28 #include "crule.h"
  29 #include "ircd_features.h"
  30 #include "fileio.h"
  31 #include "gline.h"
  32 #include "hash.h"
  33 #include "ircd.h"
  34 #include "ircd_alloc.h"
  35 #include "ircd_auth.h"
  36 #include "ircd_chattr.h"
  37 #include "ircd_log.h"
  38 #include "ircd_reply.h"
  39 #include "ircd_snprintf.h"
  40 #include "ircd_string.h"
  41 #include "list.h"
  42 #include "listener.h"
  43 #include "match.h"
  44 #include "motd.h"
  45 #include "numeric.h"
  46 #include "numnicks.h"
  47 #include "opercmds.h"
  48 #include "parse.h"
  49 #include "res.h"
  50 #include "s_bsd.h"
  51 #include "s_conf.h"
  52 #include "s_debug.h"
  53 #include "s_misc.h"
  54 #include "send.h"
  55 #include "struct.h"
  56 #include "sys.h"
  57 #include <stdlib.h>
  58 #include <stdio.h>
  59 #include <string.h>
  60 #include <arpa/inet.h>
  61 #define MAX_STRINGS 80 /* Maximum number of feature params. */
  62   extern struct LocalConf   localConf;
  63   extern struct DenyConf*   denyConfList;
  64   extern struct CRuleConf*  cruleConfList;
  65   extern struct ServerConf* serverConfList;
  66   extern struct s_map*      GlobalServiceMapList;
  67   extern struct qline*      GlobalQuarantineList;
  68
  69   int yylex(void);
  70   /* Now all the globals we need :/... */
  71   int tping, tconn, maxlinks, sendq, port, invert, stringno;
  72   char *name, *pass, *host, *ip, *username, *origin, *hub_limit;
  73   char *stringlist[MAX_STRINGS];
  74   struct ConnectionClass *c_class;
  75   struct DenyConf *dconf;
  76   struct ServerConf *sconf;
  77   struct s_map *smap;
  78   struct Privs privs;
  79   struct Privs privs_dirty;
  80
  81 static void parse_error(char *pattern,...) {
  82   static char error_buffer[1024];
  83   va_list vl;
  84   va_start(vl,pattern);
  85   ircd_vsnprintf(NULL, error_buffer, sizeof(error_buffer), pattern, vl);
  86   va_end(vl);
  87   yyerror(error_buffer);
  88 }
  89
  90 %}
  91
  92 %token <text> QSTRING
  93 %token <num> NUMBER
  94
  95 %token GENERAL
  96 %token ADMIN
  97 %token LOCATION
  98 %token CONTACT
  99 %token CONNECT
 100 %token CLASS
 101 %token CHANNEL
 102 %token PINGFREQ
 103 %token CONNECTFREQ
 104 %token MAXLINKS
 105 %token MAXHOPS
 106 %token SENDQ
 107 %token NAME
 108 %token HOST
 109 %token IP
 110 %token USERNAME
 111 %token PASS
 112 %token LOCAL
 113 %token SECONDS
 114 %token MINUTES
 115 %token HOURS
 116 %token DAYS
 117 %token WEEKS
 118 %token MONTHS
 119 %token YEARS
 120 %token DECADES
 121 %token BYTES
 122 %token KBYTES
 123 %token MBYTES
 124 %token GBYTES
 125 %token TBYTES
 126 %token SERVER
 127 %token PORT
 128 %token MASK
 129 %token HUB
 130 %token LEAF
 131 %token UWORLD
 132 %token YES
 133 %token NO
 134 %token OPER
 135 %token VHOST
 136 %token HIDDEN
 137 %token MOTD
 138 %token JUPE
 139 %token NICK
 140 %token NUMERIC
 141 %token DESCRIPTION
 142 %token CLIENT
 143 %token KILL
 144 %token CRULE
 145 %token REAL
 146 %token REASON
 147 %token TFILE
 148 %token RULE
 149 %token ALL
 150 %token FEATURES
 151 %token QUARANTINE
 152 %token PSEUDO
 153 %token PREPEND
 154 %token USERMODE
 155 %token IAUTH
 156 %token TIMEOUT
 157 %token FAST
 158 /* and now a lot of privileges... */
 159 %token TPRIV_CHAN_LIMIT TPRIV_MODE_LCHAN TPRIV_DEOP_LCHAN TPRIV_WALK_LCHAN
 160 %token TPRIV_LOCAL_KILL TPRIV_REHASH TPRIV_RESTART TPRIV_DIE
 161 %token TPRIV_GLINE TPRIV_LOCAL_GLINE TPRIV_LOCAL_JUPE TPRIV_LOCAL_BADCHAN
 162 %token TPRIV_LOCAL_OPMODE TPRIV_OPMODE TPRIV_SET TPRIV_WHOX TPRIV_BADCHAN
 163 %token TPRIV_SEE_CHAN TPRIV_SHOW_INVIS TPRIV_SHOW_ALL_INVIS TPRIV_PROPAGATE
 164 %token TPRIV_UNLIMIT_QUERY TPRIV_DISPLAY TPRIV_SEE_OPERS TPRIV_WIDE_GLINE
 165 %token TPRIV_FORCE_OPMODE TPRIV_FORCE_LOCAL_OPMODE TPRIV_APASS_OPMODE
 166 /* and some types... */
 167 %type <num> sizespec
 168 %type <num> timespec timefactor factoredtimes factoredtime
 169 %type <num> expr yesorno privtype
 170 %left '+' '-'
 171 %left '*' '/'
 172
 173 %union{
 174  char *text;
 175  int num;
 176 }
 177
 178 %%
 179 /* Blocks in the config file... */
 180 blocks: blocks block | block;
 181 block: adminblock | generalblock | classblock | connectblock |
 182        uworldblock | operblock | portblock | jupeblock | clientblock |
 183        killblock | cruleblock | motdblock | featuresblock | quarantineblock |
 184        pseudoblock | iauthblock | error;
 185
 186 /* The timespec, sizespec and expr was ripped straight from
 187  * ircd-hybrid-7. */
 188 timespec: expr | factoredtimes;
 189
 190 factoredtimes: factoredtimes factoredtime
 191 {
 192   $$ = $1 + $2;
 193 } | factoredtime;
 194
 195 factoredtime: expr timefactor
 196 {
 197   $$ = $1 * $2;
 198 };
 199
 200 timefactor: SECONDS { $$ = 1; }
 201 | MINUTES { $$ = 60; }
 202 | HOURS { $$ = 60 * 60; }
 203 | DAYS { $$ = 60 * 60 * 24; }
 204 | WEEKS { $$ = 60 * 60 * 24 * 7; }
 205 | MONTHS { $$ = 60 * 60 * 24 * 7 * 4; }
 206 | YEARS { $$ = 60 * 60 * 24 * 365; }
 207 | DECADES { $$ = 60 * 60 * 24 * 365 * 10; };
 208
 209
 210 sizespec:       expr    {
 211                         $$ = $1;
 212                 }
 213                 | expr BYTES  {
 214                         $$ = $1;
 215                 }
 216                 | expr KBYTES {
 217                         $$ = $1 * 1024;
 218                 }
 219                 | expr MBYTES {
 220                         $$ = $1 * 1024 * 1024;
 221                 }
 222                 | expr GBYTES {
 223                         $$ = $1 * 1024 * 1024 * 1024;
 224                 }
 225                 | expr TBYTES {
 226                         $$ = $1 * 1024 * 1024 * 1024;
 227                 }
 228                 ;
 229
 230 /* this is an arithmetic expression */
 231 expr: NUMBER
 232                 {
 233                         $$ = $1;
 234                 }
 235                 | expr '+' expr {
 236                         $$ = $1 + $3;
 237                 }
 238                 | expr '-' expr {
 239                         $$ = $1 - $3;
 240                 }
 241                 | expr '*' expr {
 242                         $$ = $1 * $3;
 243                 }
 244                 | expr '/' expr {
 245                         $$ = $1 / $3;
 246                 }
 247 /* leave this out until we find why it makes BSD yacc dump core -larne
 248                 | '-' expr  %prec NEG {
 249                         $$ = -$2;
 250                 } */
 251                 | '(' expr ')' {
 252                         $$ = $2;
 253                 }
 254                 ;
 255
 256 jupeblock: JUPE '{' jupeitems '}' ';' ;
 257 jupeitems: jupeitem jupeitems | jupeitem;
 258 jupeitem: jupenick | error;
 259 jupenick: NICK '=' QSTRING
 260 {
 261   addNickJupes($3);
 262   MyFree($3);
 263 } ';';
 264
 265 generalblock: GENERAL '{' generalitems '}'
 266 {
 267   if (localConf.name == NULL)
 268     parse_error("Your General block must contain a name.");
 269   if (localConf.numeric == 0)
 270     parse_error("Your General block must contain a numeric (between 1 and 4095).");
 271 } ';' ;
 272 generalitems: generalitem generalitems | generalitem;
 273 generalitem: generalnumeric | generalname | generalvhost | generaldesc | error;
 274 generalnumeric: NUMERIC '=' NUMBER ';'
 275 {
 276   if (localConf.numeric == 0)
 277     localConf.numeric = $3;
 278   else if (localConf.numeric != $3)
 279     parse_error("Redefinition of server numeric %i (%i)", $3,
 280                 localConf.numeric);
 281 };
 282
 283 generalname: NAME '=' QSTRING ';'
 284 {
 285   if (localConf.name == NULL)
 286     localConf.name = $3;
 287   else {
 288     if (strcmp(localConf.name, $3))
 289       parse_error("Redefinition of server name %s (%s)", $3,
 290                   localConf.name);
 291     MyFree($3);
 292   }
 293 };
 294
 295 generaldesc: DESCRIPTION '=' QSTRING ';'
 296 {
 297   MyFree(localConf.description);
 298   localConf.description = $3;
 299   ircd_strncpy(cli_info(&me), $3, REALLEN);
 300 };
 301
 302 generalvhost: VHOST '=' QSTRING ';'
 303 {
 304   struct irc_in_addr addr;
 305   if (!ircd_aton(&addr, $3))
 306       parse_error("Invalid virtual host '%s'.", $3);
 307   else if (irc_in_addr_is_ipv4(&addr))
 308     memcpy(&VirtualHost_v4.addr, &addr, sizeof(addr));
 309   else
 310     memcpy(&VirtualHost_v6.addr, &addr, sizeof(addr));
 311   MyFree($3);
 312 };
 313
 314 adminblock: ADMIN '{' adminitems '}'
 315 {
 316   if (localConf.location1 == NULL)
 317     DupString(localConf.location1, "");
 318   if (localConf.location2 == NULL)
 319     DupString(localConf.location2, "");
 320   if (localConf.contact == NULL)
 321     DupString(localConf.contact, "");
 322 } ';';
 323 adminitems: adminitems adminitem | adminitem;
 324 adminitem: adminlocation | admincontact | error;
 325 adminlocation: LOCATION '=' QSTRING ';'
 326 {
 327   if (localConf.location1 == NULL)
 328     localConf.location1 = $3;
 329   else if (localConf.location2 == NULL)
 330     localConf.location2 = $3;
 331   else /* Otherwise just drop it. -A1kmm */
 332     MyFree($3);
 333 };
 334 admincontact: CONTACT '=' QSTRING ';'
 335 {
 336  MyFree(localConf.contact);
 337  localConf.contact = $3;
 338 };
 339
 340 classblock: CLASS {
 341   tping = 90;
 342 } '{' classitems '}'
 343 {
 344   if (name != NULL)
 345   {
 346     struct ConnectionClass *c_class;
 347     add_class(name, tping, tconn, maxlinks, sendq);
 348     c_class = find_class(name);
 349     MyFree(c_class->default_umode);
 350     c_class->default_umode = pass;
 351     memcpy(&c_class->privs, &privs, sizeof(c_class->privs));
 352     memcpy(&c_class->privs_dirty, &privs_dirty, sizeof(c_class->privs_dirty));
 353   }
 354   else {
 355    parse_error("Missing name in class block");
 356   }
 357   name = NULL;
 358   pass = NULL;
 359   tconn = 0;
 360   maxlinks = 0;
 361   sendq = 0;
 362   memset(&privs, 0, sizeof(privs));
 363   memset(&privs_dirty, 0, sizeof(privs_dirty));
 364 } ';';
 365 classitems: classitem classitems | classitem;
 366 classitem: classname | classpingfreq | classconnfreq | classmaxlinks |
 367            classsendq | classusermode | priv | error;
 368 classname: NAME '=' QSTRING ';'
 369 {
 370   MyFree(name);
 371   name = $3;
 372 };
 373 classpingfreq: PINGFREQ '=' timespec ';'
 374 {
 375   tping = $3;
 376 };
 377 classconnfreq: CONNECTFREQ '=' timespec ';'
 378 {
 379   tconn = $3;
 380 };
 381 classmaxlinks: MAXLINKS '=' expr ';'
 382 {
 383   maxlinks = $3;
 384 };
 385 classsendq: SENDQ '=' sizespec ';'
 386 {
 387   sendq = $3;
 388 };
 389 classusermode: USERMODE '=' QSTRING ';'
 390 {
 391   MyFree(pass);
 392   pass = $3;
 393 };
 394
 395 connectblock: CONNECT
 396 {
 397  maxlinks = 65535;
 398 } '{' connectitems '}'
 399 {
 400  if (name != NULL && pass != NULL && host != NULL && c_class != NULL
 401      && !strchr(host, '*') && !strchr(host, '?'))
 402  {
 403    struct ConfItem *aconf = make_conf(CONF_SERVER);
 404    aconf->name = name;
 405    aconf->origin_name = origin;
 406    aconf->passwd = pass;
 407    aconf->conn_class = c_class;
 408    aconf->address.port = port;
 409    aconf->host = host;
 410    aconf->maximum = maxlinks;
 411    aconf->hub_limit = hub_limit;
 412    lookup_confhost(aconf);
 413  }
 414  else
 415  {
 416    MyFree(name);
 417    MyFree(pass);
 418    MyFree(host);
 419    MyFree(origin);
 420    MyFree(hub_limit);
 421    parse_error("Bad connect block");
 422  }
 423  name = pass = host = origin = hub_limit = NULL;
 424  c_class = NULL;
 425  port = 0;
 426 }';';
 427 connectitems: connectitem connectitems | connectitem;
 428 connectitem: connectname | connectpass | connectclass | connecthost
 429               | connectport | connectvhost | connectleaf | connecthub
 430               | connecthublimit | connectmaxhops | error;
 431 connectname: NAME '=' QSTRING ';'
 432 {
 433  MyFree(name);
 434  name = $3;
 435 };
 436 connectpass: PASS '=' QSTRING ';'
 437 {
 438  MyFree(pass);
 439  pass = $3;
 440 };
 441 connectclass: CLASS '=' QSTRING ';'
 442 {
 443  c_class = find_class($3);
 444  MyFree($3);
 445 };
 446 connecthost: HOST '=' QSTRING ';'
 447 {
 448  MyFree(host);
 449  host = $3;
 450 };
 451 connectport: PORT '=' NUMBER ';'
 452 {
 453  port = $3;
 454 };
 455 connectvhost: VHOST '=' QSTRING ';'
 456 {
 457  MyFree(origin);
 458  origin = $3;
 459 };
 460 connectleaf: LEAF ';'
 461 {
 462  maxlinks = 0;
 463 };
 464 connecthub: HUB ';'
 465 {
 466  MyFree(hub_limit);
 467  DupString(hub_limit, "*");
 468 };
 469 connecthublimit: HUB '=' QSTRING ';'
 470 {
 471  MyFree(hub_limit);
 472  hub_limit = $3;
 473 };
 474 connectmaxhops: MAXHOPS '=' expr ';'
 475 {
 476   maxlinks = $3;
 477 };
 478
 479 uworldblock: UWORLD '{' uworlditems '}' ';';
 480 uworlditems: uworlditem uworlditems | uworlditem;
 481 uworlditem: uworldname | error;
 482 uworldname: NAME '=' QSTRING ';'
 483 {
 484   make_conf(CONF_UWORLD)->host = $3;
 485 };
 486
 487 operblock: OPER '{' operitems '}' ';'
 488 {
 489   if (name && pass && host && c_class)
 490   {
 491     struct ConfItem *aconf = make_conf(CONF_OPERATOR);
 492     aconf->name = name;
 493     aconf->passwd = pass;
 494     conf_parse_userhost(aconf, host);
 495     aconf->conn_class = c_class;
 496     memcpy(&aconf->privs, &privs, sizeof(aconf->privs));
 497     memcpy(&aconf->privs_dirty, &privs_dirty, sizeof(aconf->privs_dirty));
 498     if (!FlagHas(&privs_dirty, PRIV_PROPAGATE)
 499         && !FlagHas(&c_class->privs_dirty, PRIV_PROPAGATE))
 500       parse_error("Operator block for %s and class %s have no LOCAL setting", name, c_class->cc_name);
 501   }
 502   else
 503   {
 504     parse_error("operator blocks need a name, password, class and host.");
 505     MyFree(name);
 506     MyFree(pass);
 507     MyFree(host);
 508   }
 509   name = pass = host = NULL;
 510   c_class = NULL;
 511   memset(&privs, 0, sizeof(privs));
 512   memset(&privs_dirty, 0, sizeof(privs_dirty));
 513 };
 514 operitems: operitem | operitems operitem;
 515 operitem: opername | operpass | operhost | operclass | priv | error;
 516 opername: NAME '=' QSTRING ';'
 517 {
 518   MyFree(name);
 519   name = $3;
 520 };
 521 operpass: PASS '=' QSTRING ';'
 522 {
 523   MyFree(pass);
 524   pass = $3;
 525 };
 526 operhost: HOST '=' QSTRING ';'
 527 {
 528  MyFree(host);
 529  if (!strchr($3, '@'))
 530  {
 531    int uh_len;
 532    host = (char*) MyMalloc((uh_len = strlen($3)+3));
 533    ircd_snprintf(0, host, uh_len, "*@%s", $3);
 534    MyFree($3);
 535  }
 536  else
 537    host = $3;
 538 };
 539 operclass: CLASS '=' QSTRING ';'
 540 {
 541  c_class = find_class($3);
 542  MyFree($3);
 543 };
 544
 545 priv: privtype '=' yesorno ';'
 546 {
 547   FlagSet(&privs_dirty, $1);
 548   if (($3 == 1) ^ invert)
 549     FlagSet(&privs, $1);
 550   else
 551     FlagClr(&privs, $1);
 552   invert = 0;
 553 };
 554
 555 privtype: TPRIV_CHAN_LIMIT { $$ = PRIV_CHAN_LIMIT; } |
 556           TPRIV_MODE_LCHAN { $$ = PRIV_MODE_LCHAN; } |
 557           TPRIV_DEOP_LCHAN { $$ = PRIV_DEOP_LCHAN; } |
 558           TPRIV_WALK_LCHAN { $$ = PRIV_WALK_LCHAN; } |
 559           KILL { $$ = PRIV_KILL; } |
 560           TPRIV_LOCAL_KILL { $$ = PRIV_LOCAL_KILL; } |
 561           TPRIV_REHASH { $$ = PRIV_REHASH; } |
 562           TPRIV_RESTART { $$ = PRIV_RESTART; } |
 563           TPRIV_DIE { $$ = PRIV_DIE; } |
 564           TPRIV_GLINE { $$ = PRIV_GLINE; } |
 565           TPRIV_LOCAL_GLINE { $$ = PRIV_LOCAL_GLINE; } |
 566           JUPE { $$ = PRIV_JUPE; } |
 567           TPRIV_LOCAL_JUPE { $$ = PRIV_LOCAL_JUPE; } |
 568           TPRIV_LOCAL_OPMODE { $$ = PRIV_LOCAL_OPMODE; } |
 569           TPRIV_OPMODE { $$ = PRIV_OPMODE; }|
 570           TPRIV_SET { $$ = PRIV_SET; } |
 571           TPRIV_WHOX { $$ = PRIV_WHOX; } |
 572           TPRIV_BADCHAN { $$ = PRIV_BADCHAN; } |
 573           TPRIV_LOCAL_BADCHAN { $$ = PRIV_LOCAL_BADCHAN; } |
 574           TPRIV_SEE_CHAN { $$ = PRIV_SEE_CHAN; } |
 575           TPRIV_SHOW_INVIS { $$ = PRIV_SHOW_INVIS; } |
 576           TPRIV_SHOW_ALL_INVIS { $$ = PRIV_SHOW_ALL_INVIS; } |
 577           TPRIV_PROPAGATE { $$ = PRIV_PROPAGATE; } |
 578           TPRIV_UNLIMIT_QUERY { $$ = PRIV_UNLIMIT_QUERY; } |
 579           TPRIV_DISPLAY { $$ = PRIV_DISPLAY; } |
 580           TPRIV_SEE_OPERS { $$ = PRIV_SEE_OPERS; } |
 581           TPRIV_WIDE_GLINE { $$ = PRIV_WIDE_GLINE; } |
 582           LOCAL { $$ = PRIV_PROPAGATE; invert = 1; } |
 583           TPRIV_FORCE_OPMODE { $$ = PRIV_FORCE_OPMODE; } |
 584           TPRIV_FORCE_LOCAL_OPMODE { $$ = PRIV_FORCE_LOCAL_OPMODE; } |
 585           TPRIV_APASS_OPMODE { $$ = PRIV_APASS_OPMODE; } ;
 586
 587 yesorno: YES { $$ = 1; } | NO { $$ = 0; };
 588
 589 /* The port block... */
 590 portblock: PORT '{' portitems '}' ';'
 591 {
 592   if (port > 0 && port <= 0xFFFF)
 593   {
 594     add_listener(port, host, pass, tconn, tping);
 595   }
 596   else
 597   {
 598     parse_error("Bad port block");
 599   }
 600   MyFree(host);
 601   MyFree(pass);
 602   host = pass = NULL;
 603   port = tconn = tping = 0;
 604 };
 605 portitems: portitem portitems | portitem;
 606 portitem: portnumber | portvhost | portmask | portserver | porthidden | error;
 607 portnumber: PORT '=' NUMBER ';'
 608 {
 609   port = $3;
 610 };
 611
 612 portvhost: VHOST '=' QSTRING ';'
 613 {
 614   MyFree(host);
 615   host = $3;
 616 };
 617
 618 portmask: MASK '=' QSTRING ';'
 619 {
 620   MyFree(pass);
 621   pass = $3;
 622 };
 623
 624 portserver: SERVER '=' YES ';'
 625 {
 626   tconn = -1;
 627 } | SERVER '=' NO ';'
 628 {
 629   tconn = 0;
 630 };
 631
 632 porthidden: HIDDEN '=' YES ';'
 633 {
 634   tping = -1;
 635 } | HIDDEN '=' NO ';'
 636 {
 637   tping = 0;
 638 };
 639
 640 clientblock: CLIENT
 641 {
 642   maxlinks = 65535;
 643 }
 644 '{' clientitems '}' ';'
 645 {
 646   struct irc_in_addr addr;
 647   unsigned char addrbits = 0;
 648
 649   if (ip && !ipmask_parse(ip, &addr, &addrbits)) {
 650     parse_error("Invalid IP address in block");
 651     MyFree(username);
 652     MyFree(host);
 653     MyFree(ip);
 654     MyFree(pass);
 655   } else {
 656     struct ConfItem *aconf = make_conf(CONF_CLIENT);
 657     aconf->username = username;
 658     aconf->host = host;
 659     if (ip)
 660       memcpy(&aconf->address.addr, &addr, sizeof(aconf->address.addr));
 661     else
 662       memset(&aconf->address.addr, 0, sizeof(aconf->address.addr));
 663     aconf->addrbits = addrbits;
 664     aconf->name = ip;
 665     aconf->conn_class = c_class ? c_class : find_class("default");
 666     aconf->maximum = maxlinks;
 667     aconf->passwd = pass;
 668   }
 669   host = NULL;
 670   username = NULL;
 671   c_class = NULL;
 672   ip = NULL;
 673   pass = NULL;
 674 };
 675 clientitems: clientitem clientitems | clientitem;
 676 clientitem: clienthost | clientip | clientusername | clientclass | clientpass | clientmaxlinks | error;
 677 clienthost: HOST '=' QSTRING ';'
 678 {
 679   char *sep = strchr($3, '@');
 680   MyFree(host);
 681   if (sep) {
 682     *sep++ = '\0';
 683     MyFree(username);
 684     DupString(host, sep);
 685     username = $3;
 686   } else {
 687     host = $3;
 688   }
 689 };
 690 clientip: IP '=' QSTRING ';'
 691 {
 692   char *sep;
 693   sep = strchr($3, '@');
 694   MyFree(ip);
 695   if (sep) {
 696     *sep++ = '\0';
 697     MyFree(username);
 698     DupString(ip, sep);
 699     username = $3;
 700   } else {
 701     ip = $3;
 702   }
 703 };
 704 clientusername: USERNAME '=' QSTRING ';'
 705 {
 706   MyFree(username);
 707   username = $3;
 708 };
 709 clientclass: CLASS '=' QSTRING ';'
 710 {
 711   c_class = find_class($3);
 712   MyFree($3);
 713 };
 714 clientpass: PASS '=' QSTRING ';'
 715 {
 716   MyFree(pass);
 717   pass = $3;
 718 };
 719 clientmaxlinks: MAXLINKS '=' expr ';'
 720 {
 721   maxlinks = $3;
 722 };
 723
 724 killblock: KILL
 725 {
 726   dconf = (struct DenyConf*) MyCalloc(1, sizeof(*dconf));
 727 } '{' killitems '}'
 728 {
 729   if (dconf->usermask || dconf->hostmask ||dconf->realmask) {
 730     dconf->next = denyConfList;
 731     denyConfList = dconf;
 732   }
 733   else
 734   {
 735     MyFree(dconf->usermask);
 736     MyFree(dconf->hostmask);
 737     MyFree(dconf->realmask);
 738     MyFree(dconf->message);
 739     MyFree(dconf);
 740     parse_error("Bad kill block");
 741   }
 742   dconf = NULL;
 743 } ';';
 744 killitems: killitem killitems | killitem;
 745 killitem: killuhost | killreal | killusername | killreasonfile | killreason | error;
 746 killuhost: HOST '=' QSTRING ';'
 747 {
 748   char *h;
 749   MyFree(dconf->hostmask);
 750   MyFree(dconf->usermask);
 751   if ((h = strchr($3, '@')) == NULL)
 752   {
 753     DupString(dconf->usermask, "*");
 754     dconf->hostmask = $3;
 755   }
 756   else
 757   {
 758     *h++ = '\0';
 759     DupString(dconf->hostmask, h);
 760     dconf->usermask = $3;
 761   }
 762   ipmask_parse(dconf->hostmask, &dconf->address, &dconf->bits);
 763 };
 764
 765 killusername: USERNAME '=' QSTRING ';'
 766 {
 767   MyFree(dconf->usermask);
 768   dconf->usermask = $3;
 769 };
 770
 771 killreal: REAL '=' QSTRING ';'
 772 {
 773  MyFree(dconf->realmask);
 774  dconf->realmask = $3;
 775 };
 776
 777 killreason: REASON '=' QSTRING ';'
 778 {
 779  dconf->flags &= ~DENY_FLAGS_FILE;
 780  MyFree(dconf->message);
 781  dconf->message = $3;
 782 };
 783
 784 killreasonfile: TFILE '=' QSTRING ';'
 785 {
 786  dconf->flags |= DENY_FLAGS_FILE;
 787  MyFree(dconf->message);
 788  dconf->message = $3;
 789 };
 790
 791 cruleblock: CRULE
 792 {
 793   tconn = CRULE_AUTO;
 794 } '{' cruleitems '}' ';'
 795 {
 796   struct CRuleNode *node;
 797   if (host != NULL && pass != NULL && (node=crule_parse(pass)) != NULL)
 798   {
 799     struct CRuleConf *p = (struct CRuleConf*) MyMalloc(sizeof(*p));
 800     p->hostmask = host;
 801     p->rule = pass;
 802     p->type = tconn;
 803     p->node = node;
 804     p->next = cruleConfList;
 805     cruleConfList = p;
 806   }
 807   else
 808   {
 809     MyFree(host);
 810     MyFree(pass);
 811     parse_error("Bad CRule block");
 812   }
 813   host = pass = NULL;
 814   tconn = 0;
 815 };
 816
 817 cruleitems: cruleitem cruleitems | cruleitem;
 818 cruleitem: cruleserver | crulerule | cruleall | error;
 819
 820 cruleserver: SERVER '=' QSTRING ';'
 821 {
 822   MyFree(host);
 823   collapse($3);
 824   host = $3;
 825 };
 826
 827 crulerule: RULE '=' QSTRING ';'
 828 {
 829  MyFree(pass);
 830  pass = $3;
 831 };
 832
 833 cruleall: ALL '=' YES ';'
 834 {
 835  tconn = CRULE_ALL;
 836 } | ALL '=' NO ';'
 837 {
 838  tconn = CRULE_AUTO;
 839 };
 840
 841 motdblock: MOTD '{' motditems '}' ';'
 842 {
 843   if (host != NULL && pass != NULL)
 844     motd_add(host, pass);
 845   MyFree(host);
 846   MyFree(pass);
 847   host = pass = NULL;
 848 };
 849
 850 motditems: motditem motditems | motditem;
 851 motditem: motdhost | motdfile | error;
 852 motdhost: HOST '=' QSTRING ';'
 853 {
 854   host = $3;
 855 };
 856
 857 motdfile: TFILE '=' QSTRING ';'
 858 {
 859   pass = $3;
 860 };
 861
 862 featuresblock: FEATURES '{' featureitems '}' ';';
 863 featureitems: featureitems featureitem | featureitem;
 864
 865 featureitem: QSTRING
 866 {
 867   stringlist[0] = $1;
 868   stringno = 1;
 869 } '=' stringlist ';';
 870
 871 stringlist: QSTRING
 872 {
 873   stringlist[1] = $1;
 874   stringno = 2;
 875 } posextrastrings
 876 {
 877   unsigned int ii;
 878   feature_set(NULL, (const char * const *)stringlist, stringno);
 879   for (ii = 0; ii < stringno; ++ii)
 880     MyFree(stringlist[ii]);
 881 };
 882 posextrastrings: /* empty */ | extrastrings;
 883 extrastrings: extrastrings extrastring | extrastring;
 884 extrastring: QSTRING
 885 {
 886   if (stringno < MAX_STRINGS)
 887     stringlist[stringno++] = $1;
 888   else
 889     MyFree($1);
 890 };
 891
 892 quarantineblock: QUARANTINE '{' quarantineitems '}' ';';
 893 quarantineitems: quarantineitems quarantineitem | quarantineitem;
 894 quarantineitem: QSTRING '=' QSTRING ';'
 895 {
 896   struct qline *qconf = MyCalloc(1, sizeof(*qconf));
 897   qconf->chname = $1;
 898   qconf->reason = $3;
 899   qconf->next = GlobalQuarantineList;
 900   GlobalQuarantineList = qconf;
 901 };
 902
 903 pseudoblock: PSEUDO QSTRING '{'
 904 {
 905   smap = MyCalloc(1, sizeof(struct s_map));
 906   smap->command = $2;
 907 }
 908 pseudoitems '}' ';'
 909 {
 910   if (!smap->name || !smap->services)
 911   {
 912     parse_error("pseudo commands need a service name and list of target nicks.");
 913     return 0;
 914   }
 915   if (register_mapping(smap))
 916   {
 917     smap->next = GlobalServiceMapList;
 918     GlobalServiceMapList = smap;
 919   }
 920   else
 921   {
 922     struct nick_host *nh, *next;
 923     for (nh = smap->services; nh; nh = next)
 924     {
 925       next = nh->next;
 926       MyFree(nh);
 927     }
 928     MyFree(smap->name);
 929     MyFree(smap->command);
 930     MyFree(smap->prepend);
 931     MyFree(smap);
 932   }
 933   smap = NULL;
 934 };
 935
 936 pseudoitems: pseudoitem pseudoitems | pseudoitem;
 937 pseudoitem: pseudoname | pseudoprepend | pseudonick | pseudoflags | error;
 938 pseudoname: NAME '=' QSTRING ';'
 939 {
 940   MyFree(smap->name);
 941   smap->name = $3;
 942 };
 943 pseudoprepend: PREPEND '=' QSTRING ';'
 944 {
 945   MyFree(smap->prepend);
 946   smap->prepend = $3;
 947 };
 948 pseudonick: NICK '=' QSTRING ';'
 949 {
 950   char *sep = strchr($3, '@');
 951
 952   if (sep != NULL) {
 953     size_t slen = strlen($3);
 954     struct nick_host *nh = MyMalloc(sizeof(*nh) + slen);
 955     memcpy(nh->nick, $3, slen + 1);
 956     nh->nicklen = sep - $3;
 957     nh->next = smap->services;
 958     smap->services = nh;
 959   }
 960   MyFree($3);
 961 };
 962 pseudoflags: FAST ';'
 963 {
 964   smap->flags |= SMAP_FAST;
 965 };
 966
 967 iauthblock: IAUTH '{'
 968 {
 969   tconn = 60;
 970   tping = 60;
 971 } iauthitems '}' ';'
 972 {
 973   if (!host || !port) {
 974     parse_error("IAuth block needs a server name and port.");
 975     return 0;
 976   }
 977   iauth_connect(host, port, pass, tconn, tping);
 978   MyFree(pass);
 979   MyFree(host);
 980   pass = host = NULL;
 981   port = tconn = tping = 0;
 982 };
 983
 984 iauthitems: iauthitem iauthitems | iauthitem;
 985 iauthitem: iauthpass | iauthhost | iauthport | iauthconnfreq | iauthtimeout | error;
 986 iauthpass: PASS '=' QSTRING ';'
 987 {
 988   MyFree(pass);
 989   pass = $3;
 990 };
 991 iauthhost: HOST '=' QSTRING ';'
 992 {
 993   MyFree(host);
 994   host = $3;
 995 };
 996 iauthport: PORT '=' NUMBER ';'
 997 {
 998   port = $3;
 999 };
1000 iauthconnfreq: CONNECTFREQ '=' timespec ';'
1001 {
1002   tconn = $3;
1003 };
1004 iauthtimeout: TIMEOUT '=' timespec ';'
1005 {
1006   tping = $3;
1007 };