ircd/ircd_parser.y

   1 /*
   2  * ircd_parser.y: A yacc/bison parser for ircd config files.
   3  * This is part of ircu, an Internet Relay Chat server.
   4  * The contents of this file are Copyright 2001 Diane Bruce,
   5  * Andrew Miller, the ircd-hybrid team and the ircu team.
   6  *  This program is free software; you can redistribute it and/or modify
   7  *  it under the terms of the GNU General Public License as published by
   8  *  the Free Software Foundation; either version 2 of the License, or
   9  *  (at your option) any later version.
  10  *
  11  *  This program is distributed in the hope that it will be useful,
  12  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  *  GNU General Public License for more details.
  15  *
  16  *  You should have received a copy of the GNU General Public License
  17  *  along with this program; if not, write to the Free Software
  18  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307,
  19  *  USA.
  20  * $Id$
  21  */
  22 %{
  23
  24 #include "config.h"
  25 #include "s_conf.h"
  26 #include "class.h"
  27 #include "client.h"
  28 #include "crule.h"
  29 #include "ircd_features.h"
  30 #include "fileio.h"
  31 #include "gline.h"
  32 #include "hash.h"
  33 #include "ircd.h"
  34 #include "ircd_alloc.h"
  35 #include "ircd_auth.h"
  36 #include "ircd_chattr.h"
  37 #include "ircd_log.h"
  38 #include "ircd_reply.h"
  39 #include "ircd_snprintf.h"
  40 #include "ircd_string.h"
  41 #include "list.h"
  42 #include "listener.h"
  43 #include "match.h"
  44 #include "motd.h"
  45 #include "numeric.h"
  46 #include "numnicks.h"
  47 #include "opercmds.h"
  48 #include "parse.h"
  49 #include "res.h"
  50 #include "s_bsd.h"
  51 #include "s_conf.h"
  52 #include "s_debug.h"
  53 #include "s_misc.h"
  54 #include "send.h"
  55 #include "struct.h"
  56 #include "sys.h"
  57 #include <stdlib.h>
  58 #include <stdio.h>
  59 #include <string.h>
  60 #include <arpa/inet.h>
  61 #define MAX_STRINGS 80 /* Maximum number of feature params. */
  62   extern struct LocalConf   localConf;
  63   extern struct DenyConf*   denyConfList;
  64   extern struct CRuleConf*  cruleConfList;
  65   extern struct ServerConf* serverConfList;
  66   extern struct s_map*      GlobalServiceMapList;
  67   extern struct qline*      GlobalQuarantineList;
  68
  69   int yylex(void);
  70   /* Now all the globals we need :/... */
  71   int tping, tconn, maxlinks, sendq, port, invert, stringno;
  72   char *name, *pass, *host, *ip, *username, *origin, *hub_limit;
  73   char *stringlist[MAX_STRINGS];
  74   struct ConnectionClass *c_class;
  75   struct DenyConf *dconf;
  76   struct ServerConf *sconf;
  77   struct s_map *smap;
  78   struct Privs privs;
  79   struct Privs privs_dirty;
  80
  81 static void parse_error(char *pattern,...) {
  82   static char error_buffer[1024];
  83   va_list vl;
  84   va_start(vl,pattern);
  85   ircd_vsnprintf(NULL, error_buffer, sizeof(error_buffer), pattern, vl);
  86   va_end(vl);
  87   yyerror(error_buffer);
  88 }
  89
  90 %}
  91
  92 %token <text> QSTRING
  93 %token <num> NUMBER
  94 %token <text> FNAME
  95
  96 %token GENERAL
  97 %token ADMIN
  98 %token LOCATION
  99 %token CONTACT
 100 %token CONNECT
 101 %token CLASS
 102 %token CHANNEL
 103 %token PINGFREQ
 104 %token CONNECTFREQ
 105 %token MAXLINKS
 106 %token MAXHOPS
 107 %token SENDQ
 108 %token NAME
 109 %token HOST
 110 %token IP
 111 %token USERNAME
 112 %token PASS
 113 %token LOCAL
 114 %token SECONDS
 115 %token MINUTES
 116 %token HOURS
 117 %token DAYS
 118 %token WEEKS
 119 %token MONTHS
 120 %token YEARS
 121 %token DECADES
 122 %token BYTES
 123 %token KBYTES
 124 %token MBYTES
 125 %token GBYTES
 126 %token TBYTES
 127 %token SERVER
 128 %token PORT
 129 %token MASK
 130 %token HUB
 131 %token LEAF
 132 %token UWORLD
 133 %token YES
 134 %token NO
 135 %token OPER
 136 %token VHOST
 137 %token HIDDEN
 138 %token MOTD
 139 %token JUPE
 140 %token NICK
 141 %token NUMERIC
 142 %token DESCRIPTION
 143 %token CLIENT
 144 %token KILL
 145 %token CRULE
 146 %token REAL
 147 %token REASON
 148 %token TFILE
 149 %token RULE
 150 %token ALL
 151 %token FEATURES
 152 %token QUARANTINE
 153 %token PSEUDO
 154 %token PREPEND
 155 %token USERMODE
 156 %token IAUTH
 157 %token TIMEOUT
 158 %token FAST
 159 /* and now a lot of privileges... */
 160 %token TPRIV_CHAN_LIMIT TPRIV_MODE_LCHAN TPRIV_DEOP_LCHAN TPRIV_WALK_LCHAN
 161 %token TPRIV_LOCAL_KILL TPRIV_REHASH TPRIV_RESTART TPRIV_DIE
 162 %token TPRIV_GLINE TPRIV_LOCAL_GLINE TPRIV_LOCAL_JUPE TPRIV_LOCAL_BADCHAN
 163 %token TPRIV_LOCAL_OPMODE TPRIV_OPMODE TPRIV_SET TPRIV_WHOX TPRIV_BADCHAN
 164 %token TPRIV_SEE_CHAN TPRIV_SHOW_INVIS TPRIV_SHOW_ALL_INVIS TPRIV_PROPAGATE
 165 %token TPRIV_UNLIMIT_QUERY TPRIV_DISPLAY TPRIV_SEE_OPERS TPRIV_WIDE_GLINE
 166 %token TPRIV_FORCE_OPMODE TPRIV_FORCE_LOCAL_OPMODE TPRIV_APASS_OPMODE
 167 /* and some types... */
 168 %type <num> sizespec
 169 %type <num> timespec timefactor factoredtimes factoredtime
 170 %type <num> expr yesorno privtype
 171 %left '+' '-'
 172 %left '*' '/'
 173
 174 %union{
 175  char *text;
 176  int num;
 177 }
 178
 179 %%
 180 /* Blocks in the config file... */
 181 blocks: blocks block | block;
 182 block: adminblock | generalblock | classblock | connectblock |
 183        uworldblock | operblock | portblock | jupeblock | clientblock |
 184        killblock | cruleblock | motdblock | featuresblock | quarantineblock |
 185        pseudoblock | iauthblock | error;
 186
 187 /* The timespec, sizespec and expr was ripped straight from
 188  * ircd-hybrid-7. */
 189 timespec: expr | factoredtimes;
 190
 191 factoredtimes: factoredtimes factoredtime
 192 {
 193   $$ = $1 + $2;
 194 } | factoredtime;
 195
 196 factoredtime: expr timefactor
 197 {
 198   $$ = $1 * $2;
 199 };
 200
 201 timefactor: SECONDS { $$ = 1; }
 202 | MINUTES { $$ = 60; }
 203 | HOURS { $$ = 60 * 60; }
 204 | DAYS { $$ = 60 * 60 * 24; }
 205 | WEEKS { $$ = 60 * 60 * 24 * 7; }
 206 | MONTHS { $$ = 60 * 60 * 24 * 7 * 4; }
 207 | YEARS { $$ = 60 * 60 * 24 * 365; }
 208 | DECADES { $$ = 60 * 60 * 24 * 365 * 10; };
 209
 210
 211 sizespec:       expr    {
 212                         $$ = $1;
 213                 }
 214                 | expr BYTES  {
 215                         $$ = $1;
 216                 }
 217                 | expr KBYTES {
 218                         $$ = $1 * 1024;
 219                 }
 220                 | expr MBYTES {
 221                         $$ = $1 * 1024 * 1024;
 222                 }
 223                 | expr GBYTES {
 224                         $$ = $1 * 1024 * 1024 * 1024;
 225                 }
 226                 | expr TBYTES {
 227                         $$ = $1 * 1024 * 1024 * 1024;
 228                 }
 229                 ;
 230
 231 /* this is an arithmetic expression */
 232 expr: NUMBER
 233                 {
 234                         $$ = $1;
 235                 }
 236                 | expr '+' expr {
 237                         $$ = $1 + $3;
 238                 }
 239                 | expr '-' expr {
 240                         $$ = $1 - $3;
 241                 }
 242                 | expr '*' expr {
 243                         $$ = $1 * $3;
 244                 }
 245                 | expr '/' expr {
 246                         $$ = $1 / $3;
 247                 }
 248 /* leave this out until we find why it makes BSD yacc dump core -larne
 249                 | '-' expr  %prec NEG {
 250                         $$ = -$2;
 251                 } */
 252                 | '(' expr ')' {
 253                         $$ = $2;
 254                 }
 255                 ;
 256
 257 jupeblock: JUPE '{' jupeitems '}' ';' ;
 258 jupeitems: jupeitem jupeitems | jupeitem;
 259 jupeitem: jupenick | error;
 260 jupenick: NICK '=' QSTRING
 261 {
 262   addNickJupes($3);
 263 } ';';
 264
 265 generalblock: GENERAL '{' generalitems '}'
 266 {
 267   if (localConf.name == NULL)
 268     parse_error("Your General block must contain a name.");
 269   if (localConf.numeric == 0)
 270     parse_error("Your General block must contain a numeric (between 1 and 4095).");
 271 } ';' ;
 272 generalitems: generalitem generalitems | generalitem;
 273 generalitem: generalnumeric | generalname | generalvhost | generaldesc | error;
 274 generalnumeric: NUMERIC '=' NUMBER ';'
 275 {
 276   if (localConf.numeric == 0)
 277     localConf.numeric = $3;
 278   else if (localConf.numeric != $3)
 279     parse_error("Redefinition of server numeric %i (%i)", $3,
 280                 localConf.numeric);
 281 };
 282
 283 generalname: NAME '=' QSTRING ';'
 284 {
 285   if (localConf.name == NULL)
 286     DupString(localConf.name, $3);
 287   else if (strcmp(localConf.name, $3))
 288     parse_error("Redefinition of server name %s (%s)", $3,
 289                 localConf.name);
 290 };
 291
 292 generaldesc: DESCRIPTION '=' QSTRING ';'
 293 {
 294   MyFree(localConf.description);
 295   DupString(localConf.description, $3);
 296   ircd_strncpy(cli_info(&me), $3, REALLEN);
 297 };
 298
 299 generalvhost: VHOST '=' QSTRING ';'
 300 {
 301   struct irc_in_addr addr;
 302   if (!ircd_aton(&addr, $3))
 303       parse_error("Invalid virtual host '%s'.", $3);
 304   else if (irc_in_addr_is_ipv4(&addr))
 305     memcpy(&VirtualHost_v4.addr, &addr, sizeof(addr));
 306   else
 307     memcpy(&VirtualHost_v6.addr, &addr, sizeof(addr));
 308 };
 309
 310 adminblock: ADMIN '{' adminitems '}'
 311 {
 312   if (localConf.location1 == NULL)
 313     DupString(localConf.location1, "");
 314   if (localConf.location2 == NULL)
 315     DupString(localConf.location2, "");
 316   if (localConf.contact == NULL)
 317     DupString(localConf.contact, "");
 318 } ';';
 319 adminitems: adminitems adminitem | adminitem;
 320 adminitem: adminlocation | admincontact | error;
 321 adminlocation: LOCATION '=' QSTRING ';'
 322 {
 323  if (localConf.location1 == NULL)
 324   DupString(localConf.location1, $3);
 325  else if (localConf.location2 == NULL)
 326   DupString(localConf.location2, $3);
 327  /* Otherwise just drop it. -A1kmm */
 328 };
 329 admincontact: CONTACT '=' QSTRING ';'
 330 {
 331  if (localConf.contact != NULL)
 332    MyFree(localConf.contact);
 333  DupString(localConf.contact, $3);
 334 };
 335
 336 classblock: CLASS {
 337   tping = 90;
 338 } '{' classitems '}'
 339 {
 340   if (name != NULL)
 341   {
 342     struct ConnectionClass *c_class;
 343     add_class(name, tping, tconn, maxlinks, sendq);
 344     c_class = find_class(name);
 345     MyFree(c_class->default_umode);
 346     c_class->default_umode = pass;
 347     memcpy(&c_class->privs, &privs, sizeof(c_class->privs));
 348     memcpy(&c_class->privs_dirty, &privs_dirty, sizeof(c_class->privs_dirty));
 349   }
 350   else {
 351    parse_error("Missing name in class block");
 352   }
 353   name = NULL;
 354   pass = NULL;
 355   tconn = 0;
 356   maxlinks = 0;
 357   sendq = 0;
 358   memset(&privs, 0, sizeof(privs));
 359   memset(&privs_dirty, 0, sizeof(privs_dirty));
 360 } ';';
 361 classitems: classitem classitems | classitem;
 362 classitem: classname | classpingfreq | classconnfreq | classmaxlinks |
 363            classsendq | classusermode | priv | error;
 364 classname: NAME '=' QSTRING ';'
 365 {
 366   MyFree(name);
 367   DupString(name, $3);
 368 };
 369 classpingfreq: PINGFREQ '=' timespec ';'
 370 {
 371   tping = $3;
 372 };
 373 classconnfreq: CONNECTFREQ '=' timespec ';'
 374 {
 375   tconn = $3;
 376 };
 377 classmaxlinks: MAXLINKS '=' expr ';'
 378 {
 379   maxlinks = $3;
 380 };
 381 classsendq: SENDQ '=' sizespec ';'
 382 {
 383   sendq = $3;
 384 };
 385 classusermode: USERMODE '=' QSTRING ';'
 386 {
 387   MyFree(pass);
 388   DupString(pass, $3);
 389 };
 390
 391 connectblock: CONNECT
 392 {
 393  maxlinks = 65535;
 394 } '{' connectitems '}'
 395 {
 396  if (name != NULL && pass != NULL && host != NULL && c_class != NULL
 397      && !strchr(host, '*') && !strchr(host, '?'))
 398  {
 399    struct ConfItem *aconf = make_conf(CONF_SERVER);
 400    aconf->name = name;
 401    aconf->origin_name = origin;
 402    aconf->passwd = pass;
 403    aconf->conn_class = c_class;
 404    aconf->address.port = port;
 405    aconf->host = host;
 406    aconf->maximum = maxlinks;
 407    aconf->hub_limit = hub_limit;
 408    lookup_confhost(aconf);
 409  }
 410  else
 411  {
 412    MyFree(name);
 413    MyFree(pass);
 414    MyFree(host);
 415    MyFree(origin);
 416    MyFree(hub_limit);
 417    parse_error("Bad connect block");
 418  }
 419  name = pass = host = origin = hub_limit = NULL;
 420  c_class = NULL;
 421  port = 0;
 422 }';';
 423 connectitems: connectitem connectitems | connectitem;
 424 connectitem: connectname | connectpass | connectclass | connecthost
 425               | connectport | connectvhost | connectleaf | connecthub
 426               | connecthublimit | connectmaxhops | error;
 427 connectname: NAME '=' QSTRING ';'
 428 {
 429  MyFree(name);
 430  DupString(name, $3);
 431 };
 432 connectpass: PASS '=' QSTRING ';'
 433 {
 434  MyFree(pass);
 435  DupString(pass, $3);
 436 };
 437 connectclass: CLASS '=' QSTRING ';'
 438 {
 439  c_class = find_class($3);
 440 };
 441 connecthost: HOST '=' QSTRING ';'
 442 {
 443  MyFree(host);
 444  DupString(host, $3);
 445 };
 446 connectport: PORT '=' NUMBER ';'
 447 {
 448  port = $3;
 449 };
 450 connectvhost: VHOST '=' QSTRING ';'
 451 {
 452  MyFree(origin);
 453  DupString(origin, $3);
 454 };
 455 connectleaf: LEAF ';'
 456 {
 457  maxlinks = 0;
 458 };
 459 connecthub: HUB ';'
 460 {
 461  MyFree(hub_limit);
 462  DupString(hub_limit, "*");
 463 };
 464 connecthublimit: HUB '=' QSTRING ';'
 465 {
 466  MyFree(hub_limit);
 467  DupString(hub_limit, $3);
 468 };
 469 connectmaxhops: MAXHOPS '=' expr ';'
 470 {
 471   maxlinks = $3;
 472 };
 473
 474 uworldblock: UWORLD '{' uworlditems '}' ';'
 475 {
 476  if (name)
 477  {
 478   struct ConfItem *aconf = make_conf(CONF_UWORLD);
 479   aconf->host = name;
 480  }
 481  else
 482  {
 483   MyFree(name);
 484   parse_error("Bad UWorld block");
 485  }
 486  name = NULL;
 487 };
 488 uworlditems: uworlditem uworlditems | uworlditem;
 489 uworlditem: uworldname | error;
 490 uworldname: NAME '=' QSTRING ';'
 491 {
 492  MyFree(name);
 493  DupString(name, $3);
 494 };
 495
 496 operblock: OPER '{' operitems '}' ';'
 497 {
 498   if (name && pass && host && c_class)
 499   {
 500     struct ConfItem *aconf = make_conf(CONF_OPERATOR);
 501     aconf->name = name;
 502     aconf->passwd = pass;
 503     conf_parse_userhost(aconf, host);
 504     aconf->conn_class = c_class;
 505     memcpy(&aconf->privs, &privs, sizeof(aconf->privs));
 506     memcpy(&aconf->privs_dirty, &privs_dirty, sizeof(aconf->privs_dirty));
 507     if (!FlagHas(&privs_dirty, PRIV_PROPAGATE)
 508         && !FlagHas(&c_class->privs_dirty, PRIV_PROPAGATE))
 509       parse_error("Operator block for %s and class %s have no LOCAL setting", name, c_class->cc_name);
 510   }
 511   else
 512   {
 513     parse_error("operator blocks need a name, password, class and host.");
 514     MyFree(name);
 515     MyFree(pass);
 516     MyFree(host);
 517   }
 518   name = pass = host = NULL;
 519   c_class = NULL;
 520   memset(&privs, 0, sizeof(privs));
 521   memset(&privs_dirty, 0, sizeof(privs_dirty));
 522 };
 523 operitems: operitem | operitems operitem;
 524 operitem: opername | operpass | operhost | operclass | priv | error;
 525 opername: NAME '=' QSTRING ';'
 526 {
 527   MyFree(name);
 528   DupString(name, $3);
 529 };
 530 operpass: PASS '=' QSTRING ';'
 531 {
 532   MyFree(pass);
 533   DupString(pass, $3);
 534 };
 535 operhost: HOST '=' QSTRING ';'
 536 {
 537  MyFree(host);
 538  if (!strchr($3, '@'))
 539  {
 540    int uh_len;
 541    char *b = (char*) MyMalloc((uh_len = strlen($3)+3));
 542    ircd_snprintf(0, b, uh_len, "*@%s", $3);
 543    host = b;
 544  }
 545  else
 546    DupString(host, $3);
 547 };
 548 operclass: CLASS '=' QSTRING ';'
 549 {
 550  c_class = find_class($3);
 551 };
 552
 553 priv: privtype '=' yesorno ';'
 554 {
 555   FlagSet(&privs_dirty, $1);
 556   if (($3 == 1) ^ invert)
 557     FlagSet(&privs, $1);
 558   else
 559     FlagClr(&privs, $1);
 560   invert = 0;
 561 };
 562
 563 privtype: TPRIV_CHAN_LIMIT { $$ = PRIV_CHAN_LIMIT; } |
 564           TPRIV_MODE_LCHAN { $$ = PRIV_MODE_LCHAN; } |
 565           TPRIV_DEOP_LCHAN { $$ = PRIV_DEOP_LCHAN; } |
 566           TPRIV_WALK_LCHAN { $$ = PRIV_WALK_LCHAN; } |
 567           KILL { $$ = PRIV_KILL; } |
 568           TPRIV_LOCAL_KILL { $$ = PRIV_LOCAL_KILL; } |
 569           TPRIV_REHASH { $$ = PRIV_REHASH; } |
 570           TPRIV_RESTART { $$ = PRIV_RESTART; } |
 571           TPRIV_DIE { $$ = PRIV_DIE; } |
 572           TPRIV_GLINE { $$ = PRIV_GLINE; } |
 573           TPRIV_LOCAL_GLINE { $$ = PRIV_LOCAL_GLINE; } |
 574           JUPE { $$ = PRIV_JUPE; } |
 575           TPRIV_LOCAL_JUPE { $$ = PRIV_LOCAL_JUPE; } |
 576           TPRIV_LOCAL_OPMODE { $$ = PRIV_LOCAL_OPMODE; } |
 577           TPRIV_OPMODE { $$ = PRIV_OPMODE; }|
 578           TPRIV_SET { $$ = PRIV_SET; } |
 579           TPRIV_WHOX { $$ = PRIV_WHOX; } |
 580           TPRIV_BADCHAN { $$ = PRIV_BADCHAN; } |
 581           TPRIV_LOCAL_BADCHAN { $$ = PRIV_LOCAL_BADCHAN; } |
 582           TPRIV_SEE_CHAN { $$ = PRIV_SEE_CHAN; } |
 583           TPRIV_SHOW_INVIS { $$ = PRIV_SHOW_INVIS; } |
 584           TPRIV_SHOW_ALL_INVIS { $$ = PRIV_SHOW_ALL_INVIS; } |
 585           TPRIV_PROPAGATE { $$ = PRIV_PROPAGATE; } |
 586           TPRIV_UNLIMIT_QUERY { $$ = PRIV_UNLIMIT_QUERY; } |
 587           TPRIV_DISPLAY { $$ = PRIV_DISPLAY; } |
 588           TPRIV_SEE_OPERS { $$ = PRIV_SEE_OPERS; } |
 589           TPRIV_WIDE_GLINE { $$ = PRIV_WIDE_GLINE; } |
 590           LOCAL { $$ = PRIV_PROPAGATE; invert = 1; } |
 591           TPRIV_FORCE_OPMODE { $$ = PRIV_FORCE_OPMODE; } |
 592           TPRIV_FORCE_LOCAL_OPMODE { $$ = PRIV_FORCE_LOCAL_OPMODE; } |
 593           TPRIV_APASS_OPMODE { $$ = PRIV_APASS_OPMODE; } ;
 594
 595 yesorno: YES { $$ = 1; } | NO { $$ = 0; };
 596
 597 /* The port block... */
 598 portblock: PORT '{' portitems '}' ';'
 599 {
 600   if (port > 0 && port <= 0xFFFF)
 601   {
 602     add_listener(port, host, pass, tconn, tping);
 603   }
 604   else
 605   {
 606     parse_error("Bad port block");
 607   }
 608   MyFree(host);
 609   MyFree(pass);
 610   host = pass = NULL;
 611   port = tconn = tping = 0;
 612 };
 613 portitems: portitem portitems | portitem;
 614 portitem: portnumber | portvhost | portmask | portserver | porthidden | error;
 615 portnumber: PORT '=' NUMBER ';'
 616 {
 617   port = $3;
 618 };
 619
 620 portvhost: VHOST '=' QSTRING ';'
 621 {
 622   MyFree(host);
 623   DupString(host, $3);
 624 };
 625
 626 portmask: MASK '=' QSTRING ';'
 627 {
 628   MyFree(pass);
 629   DupString(pass, $3);
 630 };
 631
 632 portserver: SERVER '=' YES ';'
 633 {
 634   tconn = -1;
 635 } | SERVER '=' NO ';'
 636 {
 637   tconn = 0;
 638 };
 639
 640 porthidden: HIDDEN '=' YES ';'
 641 {
 642   tping = -1;
 643 } | HIDDEN '=' NO ';'
 644 {
 645   tping = 0;
 646 };
 647
 648 clientblock: CLIENT
 649 {
 650   maxlinks = 65535;
 651 }
 652 '{' clientitems '}' ';'
 653 {
 654   struct irc_in_addr addr;
 655   unsigned char addrbits = 0;
 656
 657   if (ip && !ipmask_parse(ip, &addr, &addrbits)) {
 658     parse_error("Invalid IP address in block");
 659     MyFree(username);
 660     MyFree(host);
 661     MyFree(ip);
 662     MyFree(pass);
 663   } else {
 664     struct ConfItem *aconf = make_conf(CONF_CLIENT);
 665     aconf->username = username;
 666     aconf->host = host;
 667     if (ip)
 668       memcpy(&aconf->address.addr, &addr, sizeof(aconf->address.addr));
 669     else
 670       memset(&aconf->address.addr, 0, sizeof(aconf->address.addr));
 671     aconf->addrbits = addrbits;
 672     aconf->name = ip;
 673     aconf->conn_class = c_class ? c_class : find_class("default");
 674     aconf->maximum = maxlinks;
 675     aconf->passwd = pass;
 676   }
 677   host = NULL;
 678   username = NULL;
 679   c_class = NULL;
 680   ip = NULL;
 681   pass = NULL;
 682 };
 683 clientitems: clientitem clientitems | clientitem;
 684 clientitem: clienthost | clientip | clientusername | clientclass | clientpass | clientmaxlinks | error;
 685 clienthost: HOST '=' QSTRING ';'
 686 {
 687   char *sep = strchr($3, '@');
 688   MyFree(host);
 689   if (sep) {
 690     *sep++ = '\0';
 691     MyFree(username);
 692     DupString(username, $3);
 693     DupString(host, sep);
 694   } else {
 695     DupString(host, $3);
 696   }
 697 };
 698 clientip: IP '=' QSTRING ';'
 699 {
 700   char *sep = strchr($3, '@');
 701   MyFree(ip);
 702   if (sep) {
 703     *sep++ = '\0';
 704     MyFree(username);
 705     DupString(username, $3);
 706     DupString(ip, sep);
 707   } else {
 708     DupString(ip, $3);
 709   }
 710 };
 711 clientusername: USERNAME '=' QSTRING ';'
 712 {
 713   MyFree(username);
 714   DupString(username, $3);
 715 };
 716 clientclass: CLASS '=' QSTRING ';'
 717 {
 718   c_class = find_class($3);
 719 };
 720 clientpass: PASS '=' QSTRING ';'
 721 {
 722   MyFree(pass);
 723   DupString(pass, $3);
 724 };
 725 clientmaxlinks: MAXLINKS '=' expr ';'
 726 {
 727   maxlinks = $3;
 728 };
 729
 730 killblock: KILL
 731 {
 732   dconf = (struct DenyConf*) MyCalloc(1, sizeof(*dconf));
 733 } '{' killitems '}'
 734 {
 735   if (dconf->usermask || dconf->hostmask ||dconf->realmask) {
 736     dconf->next = denyConfList;
 737     denyConfList = dconf;
 738   }
 739   else
 740   {
 741     MyFree(dconf->usermask);
 742     MyFree(dconf->hostmask);
 743     MyFree(dconf->realmask);
 744     MyFree(dconf->message);
 745     MyFree(dconf);
 746     parse_error("Bad kill block");
 747   }
 748   dconf = NULL;
 749 } ';';
 750 killitems: killitem killitems | killitem;
 751 killitem: killuhost | killreal | killusername | killreasonfile | killreason | error;
 752 killuhost: HOST '=' QSTRING ';'
 753 {
 754   char *u, *h;
 755   MyFree(dconf->hostmask);
 756   MyFree(dconf->usermask);
 757   if ((h = strchr($3, '@')) == NULL)
 758   {
 759     u = "*";
 760     h = $3;
 761   }
 762   else
 763   {
 764     u = $3;
 765     *h++ = '\0';
 766   }
 767   DupString(dconf->hostmask, h);
 768   DupString(dconf->usermask, u);
 769   ipmask_parse(dconf->hostmask, &dconf->address, &dconf->bits);
 770 };
 771
 772 killusername: USERNAME '=' QSTRING ';'
 773 {
 774   MyFree(dconf->usermask);
 775   DupString(dconf->usermask, $3);
 776 };
 777
 778 killreal: REAL '=' QSTRING ';'
 779 {
 780  MyFree(dconf->realmask);
 781  DupString(dconf->realmask, $3);
 782 };
 783
 784 killreason: REASON '=' QSTRING ';'
 785 {
 786  dconf->flags &= ~DENY_FLAGS_FILE;
 787  MyFree(dconf->message);
 788  DupString(dconf->message, $3);
 789 };
 790
 791 killreasonfile: TFILE '=' QSTRING ';'
 792 {
 793  dconf->flags |= DENY_FLAGS_FILE;
 794  MyFree(dconf->message);
 795  DupString(dconf->message, $3);
 796 };
 797
 798 cruleblock: CRULE
 799 {
 800   tconn = CRULE_AUTO;
 801 } '{' cruleitems '}' ';'
 802 {
 803   struct CRuleNode *node;
 804   if (host != NULL && pass != NULL && (node=crule_parse(pass)) != NULL)
 805   {
 806     struct CRuleConf *p = (struct CRuleConf*) MyMalloc(sizeof(*p));
 807     p->hostmask = host;
 808     p->rule = pass;
 809     p->type = tconn;
 810     p->node = node;
 811     p->next = cruleConfList;
 812     cruleConfList = p;
 813   }
 814   else
 815   {
 816     MyFree(host);
 817     MyFree(pass);
 818     parse_error("Bad CRule block");
 819   }
 820   host = pass = NULL;
 821   tconn = 0;
 822 };
 823
 824 cruleitems: cruleitem cruleitems | cruleitem;
 825 cruleitem: cruleserver | crulerule | cruleall | error;
 826
 827 cruleserver: SERVER '=' QSTRING ';'
 828 {
 829   MyFree(host);
 830   collapse($3);
 831   DupString(host, $3);
 832 };
 833
 834 crulerule: RULE '=' QSTRING ';'
 835 {
 836  MyFree(pass);
 837  DupString(pass, $3);
 838 };
 839
 840 cruleall: ALL '=' YES ';'
 841 {
 842  tconn = CRULE_ALL;
 843 } | ALL '=' NO ';'
 844 {
 845  tconn = CRULE_AUTO;
 846 };
 847
 848 motdblock: MOTD '{' motditems '}' ';'
 849 {
 850   if (host != NULL && pass != NULL)
 851     motd_add(host, pass);
 852   MyFree(host);
 853   MyFree(pass);
 854   host = pass = NULL;
 855 };
 856
 857 motditems: motditem motditems | motditem;
 858 motditem: motdhost | motdfile | error;
 859 motdhost: HOST '=' QSTRING ';'
 860 {
 861   DupString(host, $3);
 862 };
 863
 864 motdfile: TFILE '=' QSTRING ';'
 865 {
 866   DupString(pass, $3);
 867 };
 868
 869 featuresblock: FEATURES '{' featureitems '}' ';';
 870 featureitems: featureitems featureitem | featureitem;
 871
 872 featureitem: QSTRING
 873 {
 874   stringlist[0] = $1;
 875   stringno = 1;
 876 } '=' stringlist ';';
 877
 878 stringlist: QSTRING
 879 {
 880   stringlist[1] = $1;
 881   stringno = 2;
 882 } posextrastrings
 883 {
 884   feature_set(NULL, (const char * const *)stringlist, stringno);
 885 };
 886 posextrastrings: /* empty */ | extrastrings;
 887 extrastrings: extrastrings extrastring | extrastring;
 888 extrastring: QSTRING
 889 {
 890   if (stringno < MAX_STRINGS)
 891     stringlist[stringno++] = $1;
 892 };
 893
 894 quarantineblock: QUARANTINE '{' quarantineitems '}' ';';
 895 quarantineitems: quarantineitems quarantineitem | quarantineitem;
 896 quarantineitem: QSTRING '=' QSTRING ';'
 897 {
 898   struct qline *qconf = MyCalloc(1, sizeof(*qconf));
 899   DupString(qconf->chname, $1);
 900   DupString(qconf->reason, $3);
 901   qconf->next = GlobalQuarantineList;
 902   GlobalQuarantineList = qconf;
 903 };
 904
 905 pseudoblock: PSEUDO QSTRING '{'
 906 {
 907   smap = MyCalloc(1, sizeof(struct s_map));
 908   DupString(smap->command, $2);
 909 }
 910 pseudoitems '}' ';'
 911 {
 912   if (!smap->name || !smap->services)
 913   {
 914     parse_error("pseudo commands need a service name and list of target nicks.");
 915     return 0;
 916   }
 917   if (register_mapping(smap))
 918   {
 919     smap->next = GlobalServiceMapList;
 920     GlobalServiceMapList = smap;
 921   }
 922   else
 923   {
 924     struct nick_host *nh, *next;
 925     for (nh = smap->services; nh; nh = next)
 926     {
 927       next = nh->next;
 928       MyFree(nh);
 929     }
 930     MyFree(smap->name);
 931     MyFree(smap->command);
 932     MyFree(smap->prepend);
 933     MyFree(smap);
 934   }
 935   smap = NULL;
 936 };
 937
 938 pseudoitems: pseudoitem pseudoitems | pseudoitem;
 939 pseudoitem: pseudoname | pseudoprepend | pseudonick | pseudoflags | error;
 940 pseudoname: NAME '=' QSTRING ';'
 941 {
 942   DupString(smap->name, $3);
 943 };
 944 pseudoprepend: PREPEND '=' QSTRING ';'
 945 {
 946   DupString(smap->prepend, $3);
 947 };
 948 pseudonick: NICK '=' QSTRING ';'
 949 {
 950   char *sep = strchr($3, '@');
 951
 952   if (sep != NULL) {
 953     size_t slen = strlen($3);
 954     struct nick_host *nh = MyMalloc(sizeof(*nh) + slen);
 955     memcpy(nh->nick, $3, slen + 1);
 956     nh->nicklen = sep - $3;
 957     nh->next = smap->services;
 958     smap->services = nh;
 959   }
 960 };
 961 pseudoflags: FAST ';'
 962 {
 963   smap->flags |= SMAP_FAST;
 964 };
 965
 966 iauthblock: IAUTH '{'
 967 {
 968   tconn = 60;
 969   tping = 60;
 970 } iauthitems '}' ';'
 971 {
 972   if (!host || !port) {
 973     parse_error("IAuth block needs a server name and port.");
 974     return 0;
 975   }
 976   iauth_connect(host, port, pass, tconn, tping);
 977   MyFree(pass);
 978   MyFree(host);
 979   pass = host = NULL;
 980   port = tconn = tping = 0;
 981 };
 982
 983 iauthitems: iauthitem iauthitems | iauthitem;
 984 iauthitem: iauthpass | iauthhost | iauthport | iauthconnfreq | iauthtimeout | error;
 985 iauthpass: PASS '=' QSTRING ';'
 986 {
 987   MyFree(pass);
 988   DupString(pass, $3);
 989 };
 990 iauthhost: HOST '=' QSTRING ';'
 991 {
 992   MyFree(host);
 993   DupString(host, $3);
 994 };
 995 iauthport: PORT '=' NUMBER ';'
 996 {
 997   port = $3;
 998 };
 999 iauthconnfreq: CONNECTFREQ '=' timespec ';'
1000 {
1001   tconn = $3;
1002 };
1003 iauthtimeout: TIMEOUT '=' timespec ';'
1004 {
1005   tping = $3;
1006 };