configure.in

   1 dnl Prefered emacs editing mode: -*- shell-script -*-
   2 dnl
   3 dnl Process this file with autoconf to produce a configure script.
   4 dnl
   5 dnl Copyright (c) 1997, by Carlo Wood <carlo@runaway.xs4all.nl>
   6 dnl Copyright (C) 2001  Kevin L. Mitchell <klmitch@mit.edu>
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 1, or (at your option)
  11 dnl any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  21 dnl
  22 dnl $Id$
  23
  24 dnl Make sure we are in the correct directory (someone could have run
  25 dnl 'configure' with a wrong '--srcdir').
  26 AC_INIT(ircd/ircd.c)
  27
  28 dnl Set the default prefix
  29 AC_PREFIX_DEFAULT([$HOME])
  30 AC_MSG_CHECKING([for installation prefix])
  31 AC_CACHE_VAL(unet_cv_prefix, [unet_cv_prefix=$HOME])
  32 if test x"$prefix" != xNONE; then
  33     unet_cv_prefix=$prefix
  34 fi
  35 AC_MSG_RESULT([$unet_cv_prefix])
  36 dnl HACK WARNING: We are referencing an autoconf internal variable.  This is
  37 dnl the only way to force the prefix to be retrieved from the config.cache
  38 dnl file!
  39 ac_default_prefix=$unet_cv_prefix
  40
  41 dnl Define the input and output configuration header file.
  42 AC_CONFIG_HEADER([config.h])
  43
  44 dnl Demand at least version 2.13 of autoconf
  45 AC_PREREQ(2.13)
  46
  47 dnl Find out what type of system we are
  48 AC_CANONICAL_HOST
  49
  50 dnl This should be done early.
  51 AC_PROG_CC
  52
  53 dnl ANSIfy the C compiler whenever possible.
  54 AM_PROG_CC_STDC
  55 dnl Use -O3 instead of -O2.
  56 if test x"$CFLAGS" != x; then
  57     CFLAGS=`echo "$CFLAGS" | sed -e 's/-O2/-O3/'`
  58 fi
  59 dnl Remove -pipe during configure
  60 if test x"$CFLAGS" != x; then
  61     CFLAGS=`echo "$CFLAGS" | sed -e 's/-pipe//g'`
  62 fi
  63 dnl Notice the -g flag and deal accordingly
  64 if test x"$CFLAGS" != x; then
  65     unet_old_cflags=$CFLAGS
  66     CFLAGS=`echo "$CFLAGS" | sed -e 's/-g//g'`
  67 fi
  68 if test x"$CFLAGS" != x"$unet_old_cflags"; then
  69     # If -g was already there, force symbols to be enabled
  70     unet_cv_enable_symbols=yes
  71 fi
  72 dnl Notice the -pg flag and deal accordingly
  73 if test x"$CFLAGS" != x; then
  74     unet_old_cflags=$CFLAGS
  75     CFLAGS=`echo "$CFLAGS" | sed -e 's/-pg//g'`
  76 fi
  77 if test x"$CFLAGS" != x"$unet_old_cflags"; then
  78     # If -pg was already there, force profiling to be enabled
  79     unet_cv_enable_profile=yes
  80 fi
  81 dnl Notice the -Wall flag and deal accordingly
  82 if test x"$CFLAGS" != x; then
  83     unet_old_cflags=$CFLAGS
  84     CFLAGS=`echo "$CFLAGS" | sed -e 's/-Wall//g'`
  85 fi
  86 if test x"$CFLAGS" != x"$unet_old_cflags"; then
  87     # If -Wall was already there, force warnings to be enabled
  88     unet_cv_enable_warnings=yes
  89 fi
  90 dnl Notice the -pedantic flag and deal accordingly
  91 if test x"$CFLAGS" != x; then
  92     unet_old_cflags=$CFLAGS
  93     CFLAGS=`echo "$CFLAGS" | sed -e 's/-pedantic//g'`
  94 fi
  95 if test x"$CFLAGS" != x"$unet_old_cflags"; then
  96     # If -pedantic was already there, force pedatic to be enabled
  97     unet_cv_enable_pedantic=yes
  98 fi
  99
 100 dnl Checks for libraries.
 101
 102 dnl Locate the library containing crypt
 103 AC_SEARCH_LIBS(crypt, descrypt crypt, ,
 104 [AC_MSG_ERROR([Unable to find library containing crypt()])])
 105
 106 dnl Do all the checks necessary to figure out -lnsl / -lsocket stuff
 107 AC_LIBRARY_NET
 108
 109 dnl Look for res_mkquery.  Done after AC_LIBRARY_NET in case res_mkquery
 110 dnl is in one of those libraries somewhere.
 111 AC_SEARCH_LIBS(res_mkquery, resolv, ,
 112 [AC_MSG_ERROR([Unable to find library containing res_mkquery()])])
 113
 114 dnl Checks for header files.
 115 AC_HEADER_STDC
 116 AC_CHECK_HEADERS(poll.h sys/devpoll.h sys/event.h)
 117
 118 dnl Checks for typedefs, structures, and compiler characteristics
 119 dnl AC_C_CONST
 120 AC_C_BIGENDIAN
 121 AC_TYPE_SIZE_T
 122 AC_HEADER_TIME
 123 AC_STRUCT_TM
 124 AC_TYPE_UID_T
 125 unet_CHECK_TYPE_SIZES
 126
 127 dnl Checks for library functions.
 128 AC_CHECK_FUNCS([kqueue setrlimit getrusage times])
 129
 130 dnl Do we have restarting syscalls ?
 131 AC_SYS_RESTARTABLE_SYSCALLS
 132
 133 dnl Check for required features for admins?
 134 AC_MSG_CHECKING([for donuts])
 135 AC_MSG_RESULT([yes])
 136
 137 dnl Test for programs
 138 AC_PROG_AWK
 139 AC_PROG_MAKE_SET
 140 AC_PROG_INSTALL
 141 AC_PROG_LN_S
 142 AC_PATH_PROGS(RMPROG, rm, /bin/rm)
 143 AC_PATH_PROGS(SHPROG, sh, /bin/sh)
 144
 145 unet_NONBLOCKING
 146 unet_SIGNALS
 147
 148 dnl Add -pipe when possible
 149 unet_PIPE_CFLAGS
 150
 151 dnl Check OS for os_dep files.
 152 AC_MSG_CHECKING(for OS-dependent information)
 153 case "$host" in
 154     *-linux*)
 155         AC_MSG_RESULT([Linux ($host) found.])
 156         unet_poll_syscall=yes
 157         OSDEP_C=os_linux.c
 158         ;;
 159
 160     *-solaris*)
 161         AC_MSG_RESULT([Solaris ($host) found.])
 162         if test x"$ac_cv_header_poll_h" = xyes; then
 163             unet_poll_syscall=yes
 164         else
 165             unet_poll_syscall=no
 166         fi
 167         OSDEP_C=os_solaris.c
 168         ;;
 169
 170     *-sunos*)
 171         AC_MSG_RESULT([Solaris ($host) found.])
 172         unet_poll_syscall=no
 173         OSDEP_C=os_solaris.c
 174         ;;
 175
 176     *-openbsd*)
 177         AC_MSG_RESULT([OpenBSD ($host) found.])
 178         if test x"$ac_cv_header_poll_h" = xyes; then
 179             unet_poll_syscall=yes
 180         else
 181             unet_poll_syscall=no
 182         fi
 183         OSDEP_C=os_openbsd.c
 184         ;;
 185
 186     *-*bsd*)
 187         AC_MSG_RESULT([Generic BSD ($host) found.])
 188         if test x"$ac_cv_header_poll_h" = xyes; then
 189             unet_poll_syscall=yes
 190         else
 191             unet_poll_syscall=no
 192         fi
 193         OSDEP_C=os_bsd.c
 194         ;;
 195
 196     *-darwin*)
 197         AC_MSG_RESULT([Darwin (Mac OS X) ($host) found.])
 198         unet_poll_syscall=no
 199         OSDEP_C=os_bsd.c
 200         ;;
 201
 202     *)
 203         AC_MSG_RESULT([Unknown system type $host found.])
 204         AC_MSG_WARN([Unknown OS type; using generic routines.])
 205         unet_poll_syscall=no
 206         OSDEP_C=os_generic.c
 207         ;;
 208 esac
 209 AC_SUBST(OSDEP_C)
 210
 211 dnl Check user configuration options
 212 dnl Start with --enable-poll
 213 AC_MSG_CHECKING([whether to enable use of poll()])
 214 AC_ARG_ENABLE([poll],
 215 [  --enable-poll           Force poll to be used regardless of whether or not
 216                           it is a system call],
 217 [unet_cv_enable_poll=$enable_poll],
 218 [AC_CACHE_VAL(unet_cv_enable_poll,
 219 [unet_cv_enable_poll=$unet_poll_syscall])])
 220
 221 # Force poll to be disabled if there is no poll.h
 222 if test x"$ac_cv_header_poll_h" != xyes; then
 223     unet_cv_enable_poll=no
 224 fi
 225
 226 AC_MSG_RESULT([$unet_cv_enable_poll])
 227
 228 if test x"$unet_cv_enable_poll" = xyes; then
 229     AC_DEFINE([USE_POLL], , [Specify whether or not to use poll()])
 230     ENGINE_C=engine_poll.c
 231 else
 232     ENGINE_C=engine_select.c
 233 fi
 234 AC_SUBST(ENGINE_C)
 235
 236 dnl Now look for --enable-debug
 237 AC_MSG_CHECKING([whether to enable debug mode])
 238 AC_ARG_ENABLE([debug],
 239 [  --enable-debug          Turn on debugging mode],
 240 [unet_cv_enable_debug=$enable_debug],
 241 [AC_CACHE_VAL(unet_cv_enable_debug,
 242 [unet_cv_enable_debug=no])])
 243 AC_MSG_RESULT([$unet_cv_enable_debug])
 244
 245 if test x"$unet_cv_enable_debug" = xyes; then
 246     AC_DEFINE([DEBUGMODE], , [Enable debugging code])
 247 fi
 248
 249 dnl Now look for --enable-leak-detect
 250 AC_MSG_CHECKING([whether to enable leak detection])
 251 AC_ARG_WITH([leak-detect],
 252 [  --with-leak-detect          Turn on the leak detector(requires patched boehm)],
 253 [unet_cv_with_leak_detect=$with_leak_detect],
 254 [AC_CACHE_VAL(unet_cv_with_leak_detect,
 255 [unet_cv_with_leak_detect=no])])
 256 AC_MSG_RESULT([$unet_cv_enable_leak_detect])
 257
 258 if test x"$unet_cv_with_leak_detect" != xno; then
 259     LIBS="-lgc $LIBS"
 260     CFLAGS="-DMDEBUG $CFLAGS"
 261     if test x"$unet_cv_with_leak_detect" != xyes; then
 262        LIBS="-L$unet_cv_with_leak_detect $LIBS"
 263     fi
 264 fi
 265
 266 dnl And now for --disable-asserts
 267 AC_MSG_CHECKING([whether to enable asserts])
 268 AC_ARG_ENABLE([asserts],
 269 [  --disable-asserts       Disable assertion checking],
 270 [unet_cv_enable_asserts=$enable_asserts],
 271 [AC_CACHE_VAL(unet_cv_enable_asserts,
 272 [unet_cv_enable_asserts=yes])])
 273 AC_MSG_RESULT([$unet_cv_enable_asserts])
 274
 275 if test x"$unet_cv_enable_asserts" = xno; then
 276     AC_DEFINE([NDEBUG], , [Disable assertions])
 277 fi
 278
 279 dnl Check for --enable-symbols
 280 AC_MSG_CHECKING([whether to enable debugging symbols])
 281 AC_ARG_ENABLE([symbols],
 282 [  --disable-symbols       Disable debugging symbols (remove -g from CFLAGS)],
 283 [unet_cv_enable_symbols=$enable_symbols],
 284 [AC_CACHE_VAL(unet_cv_enable_symbols,
 285 [unet_cv_enable_symbols=yes])])
 286 AC_MSG_RESULT([$unet_cv_enable_symbols])
 287
 288 if test x"$unet_cv_enable_symbols" = xyes; then
 289     CFLAGS="-g $CFLAGS"
 290 fi
 291
 292 dnl Now check for --enable-profile
 293 AC_MSG_CHECKING([whether to enable profiling support (gprof)])
 294 AC_ARG_ENABLE([profile],
 295 [  --enable-profile        Enable profiling support (add -pg to CFLAGS)],
 296 [unet_cv_enable_profile=$enable_profile],
 297 [AC_CACHE_VAL(unet_cv_enable_profile,
 298 [unet_cv_enable_profile=no])])
 299 AC_MSG_RESULT([$unet_cv_enable_profile])
 300
 301 if test x"$unet_cv_enable_profile" = xyes; then
 302     CFLAGS="-pg $CFLAGS"
 303 fi
 304
 305 dnl Now check for --enable-pedantic
 306 AC_MSG_CHECKING([whether to enable pedantic compiler warnings])
 307 AC_ARG_ENABLE([pedantic],
 308 [  --enable-pedantic       Enable pedantic warnings (add -pedantic to CFLAGS)],
 309 [unet_cv_enable_pedantic=$enable_pedantic],
 310 [AC_CACHE_VAL(unet_cv_enable_pedantic,
 311 [unet_cv_enable_pedantic=no])])
 312 AC_MSG_RESULT([$unet_cv_enable_pedantic])
 313
 314 if test x"$unet_cv_enable_pedantic" = xyes; then
 315     CFLAGS="-pedantic $CFLAGS"
 316 fi
 317
 318 dnl Now check for --enable-warnings
 319 AC_MSG_CHECKING([whether to enable compiler warnings])
 320 AC_ARG_ENABLE([warnings],
 321 [  --enable-warnings       Enable warnings (add -Wall to CFLAGS)],
 322 [unet_cv_enable_warnings=$enable_warnings],
 323 [AC_CACHE_VAL(unet_cv_enable_warnings,
 324 [unet_cv_enable_warnings=no])])
 325 AC_MSG_RESULT([$unet_cv_enable_warnings])
 326
 327 if test x"$unet_cv_enable_warnings" = xyes; then
 328     CFLAGS="-Wall $CFLAGS"
 329 fi
 330
 331 dnl --disable-inlines check...
 332 AC_MSG_CHECKING([whether to enable inlining for a few critical functions])
 333 AC_ARG_ENABLE([inlines],
 334 [  --disable-inlines       Disable inlining for a few critical functions],
 335 [unet_cv_enable_inlines=$enable_inlines],
 336 [AC_CACHE_VAL(unet_cv_enable_inlines,
 337 [unet_cv_enable_inlines=yes])])
 338 AC_MSG_RESULT([$unet_cv_enable_inlines])
 339
 340 if test x"$unet_cv_enable_inlines" = xyes; then
 341     AC_DEFINE([FORCEINLINE], , [Force inlining for a few critical functions])
 342 fi
 343
 344 dnl --disable-devpoll check...
 345 AC_MSG_CHECKING([whether to enable the /dev/poll event engine])
 346 AC_ARG_ENABLE([devpoll],
 347 [  --disable-devpoll       Disable the /dev/poll-based engine],
 348 [unet_cv_enable_devpoll=$enable_devpoll],
 349 [AC_CACHE_VAL(unet_cv_enable_devpoll,
 350 [unet_cv_enable_devpoll=yes])])
 351
 352 if test x"$ac_cv_header_sys_devpoll_h" = xno; then
 353     unet_cv_enable_devpoll=no
 354 fi
 355
 356 AC_MSG_RESULT([$unet_cv_enable_devpoll])
 357
 358 if test x"$unet_cv_enable_devpoll" != xno; then
 359     AC_DEFINE([USE_DEVPOLL], , [Define to enable the /dev/poll engine])
 360     ENGINE_C="engine_devpoll.c $ENGINE_C"
 361 fi
 362
 363 dnl --disable-kqueue check...
 364 AC_MSG_CHECKING([whether to enable the kqueue event engine])
 365 AC_ARG_ENABLE([kqueue],
 366 [  --disable-kqueue        Disable the kqueue-based engine],
 367 [unet_cv_enable_kqueue=$enable_kqueue],
 368 [AC_CACHE_VAL(unet_cv_enable_kqueue,
 369 [unet_cv_enable_kqueue=yes])])
 370
 371 if test x"$ac_cv_header_sys_event_h" = xno -o x"$ac_cv_func_kqueue" = xno; then
 372     unet_cv_enable_kqueue=no
 373 fi
 374
 375 AC_MSG_RESULT([$unet_cv_enable_kqueue])
 376
 377 if test x"$unet_cv_enable_kqueue" != xno; then
 378     AC_DEFINE([USE_KQUEUE], , [Define to enable the kqueue engine])
 379     ENGINE_C="engine_kqueue.c $ENGINE_C"
 380 fi
 381
 382 dnl --disable-adns check...
 383 AC_MSG_CHECKING([whether to enable the adns resolver engine])
 384 AC_ARG_ENABLE([adns],
 385 [  --disable-adns          Disable adns resolver],
 386 [unet_cv_enable_adns=$enable_adns],
 387 [AC_CACHE_VAL(unet_cv_enable_adns,
 388 [unet_cv_enable_adns=yes])])
 389
 390 AC_MSG_RESULT([$unet_cv_enable_adns])
 391
 392 if test x"$unet_cv_enable_adns" != xno; then
 393     AC_DEFINE([USE_ADNS], , [Define to enable the adns resolver])
 394     AC_CONFIG_SUBDIRS([adns])
 395     RES_C="res_adns.c"
 396     LIBS="../adns/src/libadns.a $LIBS"
 397     ADNS_SUBDIR="adns"
 398 else
 399     RES_C="res_libresolv.c"
 400     ADNS_SUBDIR=""
 401
 402     dnl Look for res_mkquery.  Done after AC_LIBRARY_NET in case res_mkquery
 403     dnl is in one of those libraries somewhere.
 404     AC_SEARCH_LIBS(res_mkquery, resolv, ,
 405     [AC_MSG_ERROR([Unable to find library containing res_mkquery()])])
 406 fi
 407 AC_SUBST(RES_C)
 408 AC_SUBST(ADNS_SUBDIR)
 409
 410 dnl --with-symlink lets us set the name of the symlink; defaults to "ircd"
 411 AC_MSG_CHECKING([what name to give the symlink])
 412 AC_ARG_WITH([symlink],
 413 [  --with-symlink=name     Name to give the symlink; if name is "no," no
 414                           symlink will be created.],
 415 [unet_cv_with_symlink=$with_symlink],
 416 [AC_CACHE_VAL(unet_cv_with_symlink,
 417 [unet_cv_with_symlink="ircd"])])
 418
 419 if test x"$unet_cv_with_symlink" = xyes; then
 420     unet_cv_with_symlink="ircd"
 421 fi
 422
 423 AC_MSG_RESULT([$unet_cv_with_symlink])
 424
 425 if test x"$unet_cv_with_symlink" = xno; then
 426     INSTALL_RULE=install-no-symlink
 427     SYMLINK=
 428 else
 429     INSTALL_RULE=install-with-symlink
 430     SYMLINK=$unet_cv_with_symlink
 431 fi
 432 AC_SUBST(INSTALL_RULE)
 433 AC_SUBST(SYMLINK)
 434
 435 dnl --with-mode lets us set the permissions on the binary
 436 AC_MSG_CHECKING([what permissions to set on the installed binary])
 437 AC_ARG_WITH([mode],
 438 [  --with-mode=mode        Permissions (in octal) to give the binary],
 439 [unet_cv_with_mode=$with_mode],
 440 [AC_CACHE_VAL(unet_cv_with_mode,
 441 [unet_cv_with_mode=711])])
 442
 443 if test x"$unet_cv_with_mode" = xyes -o x"$unet_cv_with_mode" = xno; then
 444     unet_cv_with_mode=711
 445 fi
 446
 447 AC_MSG_RESULT([$unet_cv_with_mode])
 448
 449 IRCDMODE=$unet_cv_with_mode
 450 AC_SUBST(IRCDMODE)
 451
 452 dnl --with-owner lets us set the owner of the binary
 453 changequote(,)dnl
 454 unet_uid=`id | sed -e 's/.*uid=[0-9]*(//' -e 's/).*//' 2> /dev/null`
 455 changequote([,])dnl
 456 AC_MSG_CHECKING([which user should own the installed binary])
 457 AC_ARG_WITH([owner],
 458 [  --with-owner=owner      Specify owner of the installed binary],
 459 [unet_cv_with_owner=$with_owner],
 460 [AC_CACHE_VAL(unet_cv_with_owner,
 461 [unet_cv_with_owner=$unet_uid])])
 462
 463 if test x"$unet_cv_with_owner" = xyes -o x"$unet_cv_with_owner" = xno; then
 464     unet_cv_with_owner=$unet_uid
 465 fi
 466
 467 AC_MSG_RESULT([$unet_cv_with_owner])
 468
 469 IRCDOWN=$unet_cv_with_owner
 470 AC_SUBST(IRCDOWN)
 471
 472 dnl --with-group lets us set the group owner of the binary
 473 changequote(,)dnl
 474 unet_gid=`id | sed -e 's/.*gid=[0-9]*(//' -e 's/).*//' 2> /dev/null`
 475 changequote([,])dnl
 476 AC_MSG_CHECKING([which group should own the installed binary])
 477 AC_ARG_WITH([group],
 478 [  --with-group=group      Specify group owner of the installed binary],
 479 [unet_cv_with_group=$with_group],
 480 [AC_CACHE_VAL(unet_cv_with_group,
 481 [unet_cv_with_group=$unet_gid])])
 482
 483 if test x"$unet_cv_with_group" = xyes -o x"$unet_cv_with_group" = xno; then
 484     unet_cv_with_group=$unet_gid
 485 fi
 486
 487 AC_MSG_RESULT([$unet_cv_with_group])
 488
 489 IRCDGRP=$unet_cv_with_group
 490 AC_SUBST(IRCDGRP)
 491
 492 dnl --with-domain lets us set the domain name for some statistics-gathering
 493 unet_domain=
 494 if test -f /etc/resolv.conf; then
 495     unet_domain=`awk '/^domain/ { print $2; exit }' /etc/resolv.conf`
 496     if test x"$unet_domain" = x; then
 497         unet_domain=`awk '/^search/ { print $2; exit }' /etc/resolv.conf`
 498     fi
 499 fi
 500 AC_MSG_CHECKING([for site domain name])
 501 AC_ARG_WITH([domain],
 502 [  --with-domain=domain    Domain name to use in local statistics gathering],
 503 [unet_cv_with_domain=$with_domain],
 504 [AC_CACHE_VAL(unet_cv_with_domain,
 505 [unet_cv_with_domain=$unet_domain])])
 506
 507 if test x"$unet_cv_with_domain" = xyes -o x"$unet_cv_with_domain" = xno; then
 508     unet_cv_with_domain=$unet_domain
 509 fi
 510 if test x"$unet_cv_with_domain" = xno; then
 511     AC_MSG_ERROR([Unable to determine server DNS domain; use --with-domain to set it])
 512 fi
 513
 514 AC_MSG_RESULT([$unet_cv_with_domain])
 515
 516 AC_DEFINE_UNQUOTED(DOMAINNAME, "*$unet_cv_with_domain",
 517 [Domain name to be used for some statistics gathering])
 518
 519 dnl --with-chroot lets us define a directory that we are going to be using
 520 dnl as the root of our filesystem
 521 AC_MSG_CHECKING([if chroot operation is desired])
 522 AC_ARG_WITH([chroot],
 523 [  --with-chroot=dir       Specify that the server will be operated under
 524                           a different root directory given by dir.  See
 525                           doc/readme.chroot for more information.],
 526 [unet_cv_with_chroot=$with_chroot],
 527 [AC_CACHE_VAL(unet_cv_with_chroot,
 528 [unet_cv_with_chroot=no])])
 529
 530 if test x"$unet_cv_with_chroot" = xyes; then
 531     AC_MSG_ERROR([--with-chroot given with no directory.  See doc/readme.chroot.])
 532 fi
 533
 534 # Ensure there are no trailing /'s to mess us up
 535 unet_cv_with_chroot=`echo "$unet_cv_with_chroot" | sed 's%/*$%%'`
 536
 537 AC_MSG_RESULT([$unet_cv_with_chroot])
 538
 539 dnl Determine some default directory names
 540 dnl
 541 dnl HACK WARNING: We are referencing an autoconf internal variable.  This is
 542 dnl the only way to figure out what value $prefix will have when we go to do
 543 dnl the install--and the only way we can stick that value in our definitions
 544 dnl of SPATH, etc.
 545 # Deal with the annoying value "NONE" here
 546 unet_save_prefix=$prefix
 547 if test x"$prefix" = xNONE; then
 548     prefix=$ac_default_prefix
 549 else
 550     prefix=$prefix
 551 fi
 552
 553 unet_save_exec_prefix=$exec_prefix
 554 if test x"$exec_prefix" = xNONE; then
 555     exec_prefix=$prefix
 556 else
 557     exec_prefix=$exec_prefix
 558 fi
 559
 560 # Obtain the actual interesting directories
 561 unet_bindir=`eval echo "$bindir"`
 562 unet_libdir=`eval echo "$libdir"`
 563
 564 # Restore the original settings of $prefix and $exec_prefix
 565 prefix=$unet_save_prefix
 566 exec_prefix=$unet_save_exec_prefix
 567
 568 dnl Now compute the name of the binary and verify that it will work under
 569 dnl chroot operation
 570 AC_MSG_CHECKING([where the binary will be for /restart])
 571 if test x"$unet_cv_with_symlink" = xno; then
 572     unet_spath="$unet_bindir/ircd"
 573 else
 574     unet_spath="$unet_bindir/$unet_cv_with_symlink"
 575 fi
 576 AC_MSG_RESULT([$unet_spath])
 577
 578 if test x"$unet_cv_with_chroot" != xno; then
 579     if echo "$unet_spath" | grep "^$unet_cv_with_chroot" > /dev/null 2>&1; then
 580         unet_spath=`echo "$unet_spath" | sed "s%^$unet_cv_with_chroot%%"`
 581     else
 582         AC_MSG_WARN([Binary $unet_spath not relative to root directory $unet_cv_with_chroot; restarts will probably fail])
 583     fi
 584 fi
 585
 586 AC_DEFINE_UNQUOTED(SPATH, "$unet_spath", [Path to executable for restarts])
 587
 588 dnl --with-dpath sets the all-important DPATH
 589 AC_MSG_CHECKING([what the data directory should be])
 590 AC_ARG_WITH([dpath],
 591 [  --with-dpath=dir        Directory for all server data files],
 592 [unet_cv_with_dpath=$with_dpath],
 593 [AC_CACHE_VAL(unet_cv_with_dpath,
 594 [unet_cv_with_dpath=$unet_libdir])])
 595
 596 if test x"$unet_cv_with_dpath" = xyes -o x"$unet_cv_with_dpath" = xno; then
 597     unet_cv_with_dpath=$unet_libdir
 598 fi
 599
 600 # Ensure there are no trailing /'s to mess us up
 601 unet_cv_with_dpath=`echo "$unet_cv_with_dpath" | sed 's%/*$%%'`
 602
 603 AC_MSG_RESULT([$unet_cv_with_dpath])
 604
 605 if test x"$unet_cv_with_chroot" != xno; then
 606     if echo "$unet_cv_with_dpath" | grep "^$unet_cv_with_chroot" > /dev/null 2>&1; then
 607         unet_dpath=`echo "$unet_cv_with_dpath" | sed "s%^$unet_cv_with_chroot%%"`
 608     else
 609         AC_MSG_ERROR([Data directory $unet_cv_with_dpath not relative to root directory $unet_cv_with_chroot])
 610     fi
 611 else
 612     unet_dpath=$unet_cv_with_dpath
 613 fi
 614
 615 AC_DEFINE_UNQUOTED(DPATH, "$unet_dpath", [Path to data directory])
 616
 617 DPATH=$unet_cv_with_dpath
 618 AC_SUBST(DPATH)
 619
 620 dnl --with-cpath allows us to specify the configuration file
 621 AC_MSG_CHECKING([where the default configuration file resides])
 622 AC_ARG_WITH([cpath],
 623 [  --with-cpath=file       Set server configuration file],
 624 [unet_cv_with_cpath=$with_cpath],
 625 [AC_CACHE_VAL(unet_cv_with_cpath,
 626 [unet_cv_with_cpath="ircd.conf"])])
 627
 628 if test x"$unet_cv_with_cpath" = xyes -o x"$unet_cv_with_cpath" = xno; then
 629     unet_cv_with_cpath="ircd.conf"
 630 fi
 631
 632 AC_MSG_RESULT([$unet_cv_with_cpath])
 633
 634 if echo "$unet_cv_with_cpath" | grep '^/' > /dev/null 2>&1; then
 635     # Absolute path; check against chroot stuff
 636     if test x"$unet_cv_with_chroot" != xno; then
 637         if echo "$unet_cv_with_cpath" | grep "^$unet_cv_with_chroot" > /dev/null 2>&1; then
 638             unet_cpath=`echo "$unet_cv_with_cpath" | sed "s%^$unet_cv_with_chroot%%"`
 639         else
 640             AC_MSG_ERROR([Configuration file $unet_cv_with_cpath not relative to root directory $unet_cv_with_chroot])
 641         fi
 642     else
 643         unet_cpath=$unet_cv_with_cpath
 644     fi
 645 else
 646     unet_cpath=$unet_cv_with_cpath
 647 fi
 648
 649 AC_DEFINE_UNQUOTED(CPATH, "$unet_cpath", [Configuration file name])
 650
 651 dnl --with-lpath allows us to specify the default debugging log file
 652 AC_MSG_CHECKING([where to put the debugging log if debugging enabled])
 653 AC_ARG_WITH([lpath],
 654 [  --with-lpath=file       Set the debugging log file],
 655 [unet_cv_with_lpath=$with_lpath],
 656 [AC_CACHE_VAL(unet_cv_with_lpath,
 657 [unet_cv_with_lpath="ircd.log"])])
 658
 659 if test x"$unet_cv_with_lpath" = xyes -o x"$unet_cv_with_lpath" = xno; then
 660     unet_cv_with_lpath="ircd.log"
 661 fi
 662
 663 AC_MSG_RESULT([$unet_cv_with_lpath])
 664
 665 if echo "$unet_cv_with_lpath" | grep '^/' > /dev/null 2>&1; then
 666     # Absolute path; check against chroot stuff
 667     if test x"$unet_cv_with_chroot" != xno; then
 668         if echo "$unet_cv_with_lpath" | grep "^$unet_cv_with_chroot" > /dev/null 2>&1; then
 669             unet_lpath=`echo "$unet_cv_with_lpath" | sed "s%^$unet_cv_with_chroot%%"`
 670         else
 671             AC_MSG_WARN([Log file $unet_cv_with_lpath not relative to root directory $unet_cv_with_chroot; using default ircd.log instead])
 672             unet_cv_with_lpath="ircd.log"
 673             unet_lpath="ircd.log"
 674         fi
 675     else
 676         unet_lpath=$unet_cv_with_lpath
 677     fi
 678 else
 679     unet_lpath=$unet_cv_with_lpath
 680 fi
 681
 682 AC_DEFINE_UNQUOTED(LPATH, "$unet_lpath", [Path to debugging log file])
 683
 684 dnl --with-maxcon allows us to set the maximum connections
 685 unet_maxcon=`ulimit -Hn`
 686 unet_maxcon=`expr $unet_maxcon - 4`
 687 AC_MSG_CHECKING([max connections])
 688 AC_ARG_WITH([maxcon],
 689 [  --with-maxcon=maxcon    Maximum number of connections server will accept],
 690 [unet_cv_with_maxcon=$with_maxcon],
 691 [AC_CACHE_VAL(unet_cv_with_maxcon,
 692 [unet_cv_with_maxcon=$unet_maxcon])])
 693
 694 if test x"$unet_cv_with_maxcon" = xyes -o x"$unet_cv_with_maxcon" = xno; then
 695     unet_cv_with_maxcon=$unet_maxcon
 696 fi
 697
 698 AC_MSG_RESULT([$unet_cv_with_maxcon])
 699
 700 AC_DEFINE_UNQUOTED(MAXCONNECTIONS, $unet_cv_with_maxcon,
 701 [Maximum number of network connections])
 702
 703 dnl Finally really generate all output files:
 704 AC_OUTPUT(Makefile ircd/Makefile doc/Makefile, [echo timestamp > stamp-h])
 705
 706 dnl Report configuration
 707 AC_OUTPUT_COMMANDS([echo "
 708 ircu is now hopefully configured for your system.
 709
 710   Host system:         $host_os
 711   Prefix:              $prefix
 712   Asserts:             $unet_cv_enable_asserts
 713   Warnings:            $unet_cv_enable_warnings
 714   Debug:               $unet_cv_enable_debug
 715   Profile:             $unet_cv_enable_profile
 716   Head-in-sand:        $unet_cv_enable_headinsand
 717   ADNS:                $unet_cv_enable_adns
 718   Owner/mode:          $unet_cv_with_owner.$unet_cv_with_group ($unet_cv_with_mode)
 719   Chroot:              $unet_cv_with_chroot
 720
 721   Domain:              $unet_cv_with_domain
 722   DPath:               $unet_cv_with_dpath
 723   CPath:               $unet_cv_with_cpath
 724   LPath:               $unet_cv_with_lpath
 725   Maximum connections: $unet_cv_with_maxcon
 726
 727   poll() engine:       $unet_cv_enable_poll
 728   kqueue() engine:     $unet_cv_enable_kqueue
 729   /dev/poll engine:    $unet_cv_enable_devpoll
 730 "])